2
$\begingroup$

The following hyperboloid surface is created by:

ContourPlot3D[
 x^2 + y^2 - z^2 == 1, {x, -3, 3}, {y, -3, 3}, {z, -3/2, 3/2}, 
 RegionFunction -> Function[{x, y, z}, x^2 + y^2 <= 4], 
 PlotTheme -> "Classic", Boxed -> False, Axes -> False, 
 MeshFunctions -> {(Cos@Sin@#1)^2 &, (Sin@Sin@#2/2)^2 &}]

enter image description here

How can I obtain a closed, sine/cosine like space curve embedded in the surface? Below the curve model is used for the purpose of depiction

enter image description here

$\endgroup$
0
5
$\begingroup$
ParametricPlot3D[
 Evaluate@CoordinateTransform["Cylindrical" -> "Cartesian", Table[
    {Sqrt[1 + Sin[ th + d ]^2], th, Sin[ th + d ]}, {d, 0, 2 Pi, 
     2 Pi/16}
    ]],
 {th, 0, 2 Pi}
 ]

enter image description here

Manipulate[
 Graphics3D[
  GeometricTransformation[
   First@ParametricPlot3D[
     Evaluate@
      CoordinateTransform[
       "Cylindrical" -> "Cartesian", {Sqrt[1 + Sin[ m th ]^2], th, 
        Sin[m th ]}],
     {th, 0, 2 Pi}
     ],
   Dynamic@Table[RotationTransform[t, {0, 0, 1}], {t, 0, 2 Pi, 2 Pi/n}]
   ]
  ],
 {{n, 10}, 1, 25,1},
 {{m, 1}, 1, 25,1}
 ]

Can all the n curves be combined into only one, closed(head to tail), space curve? – user6043040

Manipulate[
 ParametricPlot3D[
  Evaluate@
   CoordinateTransform[
    "Cylindrical" -> "Cartesian", {Sqrt[1 + Sin[ m /n th ]^2], th, 
     Sin[m /n th ]}],
  {th, 0, 2 n Pi}
  ],
 {{n, 1}, 1, 25, 1},
 {{m, 1}, 1, 25, 1}
 ]
$\endgroup$
3
  • $\begingroup$ Can all the $n$ curves be combined into only one, closed(head to tail), space curve? $\endgroup$ – user6043040 Apr 30 '18 at 9:03
  • $\begingroup$ @user6043040 see the edit and play with it $\endgroup$ – Kuba Apr 30 '18 at 9:08
  • $\begingroup$ Thank you very much @Kuba This answers all my questions! The CoordinateTransform is so much powerful! It seems, in order to obtain denser mesh, the least common multiple of m and n has to be as larger as possible. $\endgroup$ – user6043040 Apr 30 '18 at 9:21

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.