5
$\begingroup$

I am trying to calculate symbolically the integral of the form:

$$ I(s)= \int\limits_0^{\pi/2} \dfrac{\cos t}{\sin^2 t-R^2} \; e^{-s/\cos t}\; dt $$

where 0<R=<1 and s>0.

Assuming[s>0,Integrate[Exp[-s/Cos[t]] (Cos[t])/(Sin[t]^2-R^2),{t,0,Pi/2}]]

For R=1, Mathematica gives the modified Bessel function of the second kind -BesselK[0,s]

Assuming[s>0,Integrate[Exp[-s/Cos[t]] (Cos[t])/(Sin[t]^2-1),{t,0,Pi/2}]]

(*-BesselK[0,s]*)

Please I would like to deduce a symbolic form as a function of s and R.

Thanks for any help!

$\endgroup$
3
  • 2
    $\begingroup$ It does not converge for $R<1$ $\endgroup$ Apr 28, 2018 at 12:07
  • $\begingroup$ I tried with the Cauchy principal value but mathematica also does not give result. $\endgroup$
    – Betatron
    Apr 28, 2018 at 12:13
  • 2
    $\begingroup$ Try posting on math.stackexchange.com. I have seen some incredible results there. $\endgroup$
    – yarchik
    Apr 29, 2018 at 20:24

2 Answers 2

5
$\begingroup$

You can compute this integral numerically. "PrincipalValue" method needs a sigular point in NIntegrate:

We can find this point solving:

Solve[Sin[t]^2-R^2 == 0, t]

(* {{t -> ConditionalExpression[-ArcSin[R] + 2 \[Pi] C[1], 
C[1] \[Element] Integers]}, {t -> 
ConditionalExpression[\[Pi] - ArcSin[R] + 2 \[Pi] C[1], 
C[1] \[Element] Integers]}, {t -> 
ConditionalExpression[ArcSin[R] + 2 \[Pi] C[1], 
C[1] \[Element] Integers]}, {t -> 
ConditionalExpression[\[Pi] + ArcSin[R] + 2 \[Pi] C[1], 
C[1] \[Element] Integers]}}*)

and putting to NIntegrate:

f[s_, R_] := NIntegrate[Exp[-s/Cos[t]] (Cos[t])/(Sin[t]^2 - R^2),
{t, 0, ArcSin[R], Pi/2}, Method -> "PrincipalValue"]

f[1,1]
(* -0.421024  *)
f[1, 1/2]
(* -0.615974 *)

EDITED: Finding symbolic form of integral:

Substituting to integral Sin[t]=x,-x^2+1=u^2,u=1/x we have: $$\int_1^{\infty } -\frac{\exp (-s x)}{\sqrt{x^2-1} \left(R^2 x^2-x^2+1\right)} \, dx$$

Integrate[-Exp[-s*x]/(Sqrt[x^2 - 1]*(R^2*x^2 - x^2 + 1)), {x, 1, Infinity}]

Returns unevaluated for me. Using Laplace transform:

LaplaceTransform[-Exp[-s*x]/(Sqrt[x^2 - 1]*(R^2*x^2 - x^2 + 1)), s, a]
(* -(1/((a + x) Sqrt[-1 + x^2] (1 - x^2 + R^2 x^2))) *) 

and then Integrating:

Integrate[-(1/((a + x) Sqrt[-1 + x^2] (1 - x^2 + R^2 x^2))), {x, 1, 
Infinity}, Assumptions -> {a > 0, 0 < R < 1}] // ExpandAll

(* (I a \[Pi])/(2 R - 2 a^2 R + 2 a^2 R^3) - (\[Pi] R)/(
Sqrt[1 - a^2] (2 R - 2 a^2 R + 2 a^2 R^3)) - (I a \[Pi] R^2)/(
2 R - 2 a^2 R + 2 a^2 R^3) - (I \[Pi])/(
Sqrt[1 - R^2] (2 R - 2 a^2 R + 2 a^2 R^3)) + (I \[Pi] R^2)/(
Sqrt[1 - R^2] (2 R - 2 a^2 R + 2 a^2 R^3)) + (2 R ArcSin[a])/(
Sqrt[1 - a^2] (2 R - 2 a^2 R + 2 a^2 R^3)) + (
a \[Pi]^(3/2)
R MeijerG[{{0}, {1/2, 1/2}}, {{0, 0}, {1/2}}, 1 - R^2])/(
2 R - 2 a^2 R + 2 a^2 R^3) - (
a \[Pi]^(3/2)
R^3 MeijerG[{{0}, {1/2, 1/2}}, {{0, 0}, {1/2}}, 1 - R^2])/(
2 R - 2 a^2 R + 2 a^2 R^3) *)

This Part (\[Pi] R)/(Sqrt[1 - a^2] (2 R - 2 a^2 R + 2 a^2 R^3)) and another part with I imaginary unit can be removed because is imaginary,well we need all real.

back to Inverse Laplace Transform:

InverseLaplaceTransform[#, a, s] & /@ ((2 R ArcSin[a])/(
Sqrt[1 - a^2] (2 R - 2 a^2 R + 2 a^2 R^3)) + (
a \[Pi]^(3/2)
 R MeijerG[{{0}, {1/2, 1/2}}, {{0, 0}, {1/2}}, 1 - R^2])/(
2 R - 2 a^2 R + 2 a^2 R^3) - (
a \[Pi]^(3/2)
 R^3 MeijerG[{{0}, {1/2, 1/2}}, {{0, 0}, {1/2}}, 1 - R^2])/(
2 R - 2 a^2 R + 2 a^2 R^3))

simplifying:

HoldForm[-((ArcTanh[R] Cosh[s/Sqrt[1 - R^2]])/R) + 
Re[InverseLaplaceTransform[ArcSin[a]/(
Sqrt[1 - a^2] (1 + a^2 (-1 + R^2))), a, s]]] // TeXForm

for: $0<R\leq 1$ and $s>0$.

$$\int_0^{\frac{\pi }{2}} \frac{\exp \left(-\frac{s}{\cos (t)}\right) \cos (t)}{\sin ^2(t)-R^2} \, dt=\\-\frac{\tanh ^{-1}(R) \cosh \left(\frac{s}{\sqrt{1-R^2}}\right)}{R}+\Re\left(\mathcal{L}_a^{-1}\left[\frac{\sin ^{-1}(a)}{\sqrt{1-a^2} \left(1+a^2 \left(-1+R^2\right)\right)}\right](s)\right)$$

MMA can't find Inverse Laplace Transform.


Using the convolution theorem:

$$\Re\left(\mathcal{L}_a^{-1}\left[\frac{\sin ^{-1}(a)}{\sqrt{1-a^2} \left(1+a^2 \left(-1+R^2\right)\right)}\right](s)\right)=\Re\left(\mathcal{L}_a^{-1}\left[\sin ^{-1}(a)\right](s)*\mathcal{L}_a^{-1}\left[\frac{1}{\sqrt{1-a^2}}\right](s)*\mathcal{L}_a ^{-1}\left[\frac{1}{1+a^2 \left(-1+R^2\right)}\right](s)\right)=\Re\left(\left(\frac{i I_0(t)}{t}\right)*\left( (-i I_0(t))\right)*\left( -\frac{\sinh \left(\frac{t}{\sqrt{1-R^2}}\right)}{\sqrt{1-R^2}}\right)\right)$$

where $I_0(x)$ is modified Bessel function of the first kind.

I doubt there's a closed form for the convolution.!!!

$\endgroup$
4
  • $\begingroup$ Many Thanks @Mariusz Iwaniuk, so there will not be a possibility for a symbolic calculation? $\endgroup$
    – Betatron
    Apr 28, 2018 at 14:47
  • $\begingroup$ Ok Sir, Thank you. $\endgroup$
    – Betatron
    Apr 28, 2018 at 14:51
  • $\begingroup$ Very nice, thanks @Mariusz Iwaniuk, but how did you find this result as a function of Inverse Laplace Transform. I didn't really understand. More details please. $\endgroup$
    – Betatron
    Apr 28, 2018 at 21:50
  • $\begingroup$ Thank you so much @Mariusz Iwaniuk, I will see this more in details. $\endgroup$
    – Betatron
    Apr 30, 2018 at 22:52
2
$\begingroup$

You may be interested in the series solution. As you already realized, the integral has a particularly simple form for $R=1$. Expanding around this point we get the series:

$f=\sum_{i=0}^\infty(R^2-1)^i e^{-s \sec t}\sec^{2i+1}t$.

Each term of this series can be analytically integrated. For instance, we have:

Assuming[s > 0, Integrate[E^(-s Sec[t]) Sec[t], {t, 0, Pi/2}]]
(*-BesselK[0, s]*)

Assuming[s > 0, Integrate[E^(-s Sec[t]) Sec[t]^3, {t, 0, Pi/2}]]
(*BesselK[0, s] + BesselK[1, s]/s*)

Assuming[s > 0, Integrate[E^(-s Sec[t]) Sec[t]^5, {t, 0, Pi/2}]]
(*(1 + 3/s^2) BesselK[2, s]*)

Assuming[s > 0, Integrate[E^(-s Sec[t]) Sec[t]^7, {t, 0, Pi/2}]]
(*(s (5 + s^2) BesselK[2, s] + (15 + s^2) BesselK[3, s])/s^3*)

Notice, that these integrals can be found by differentiation of the $i=0$ integral over the parameter $s$. Combining together, we obtain something like:

$I(s)=-\sum_{i=0}^\infty(R^2-1)^i\frac{d^{2i}}{ds^{2i}}\mathrm{K}[0, s]$. Please, verify the prefactors. It is quite possible that the series can be summed up.

$\endgroup$
4
  • $\begingroup$ Thank you @yarchik, I tried but I can't rewrite all these integrals according to the derivative dK[0,s]/ds. Any help please! $\endgroup$
    – Betatron
    Apr 30, 2018 at 22:50
  • 1
    $\begingroup$ If you take the zeroth term of my 1st equation and differentiate it with respect to s twice you get the first term, and so on. You do not even need to integrate term by term. Integrate only zeroth term (you have done it already) and obtain the rest by differentiation! You can verify the equivalence by the FullSimplify of the differentiation results, $\endgroup$
    – yarchik
    May 1, 2018 at 7:10
  • $\begingroup$ I have proceeded differently. I have developed the integrant for $R<<1$, I got: $\sum\limits_{n=0}^{\infty}\int\limits_0^{\pi/2}R^{2n}\frac{\cos t\exp(-s/\cos t)}{\sin^{2n+2}t}dt$. The integration of this series gives: Sum[R^(2n)Assuming[s>0,Integrate[Exp[-s/Cos[t]](Cos[t])/Sin[t]^(2n+2),{t,0,Pi/2},PrincipalValue ->True]],{n,0,Infinity}] , so the result is: (*Sum[ConditionalExpression[(R^(2n)Gamma[-(1/2)-n] MeijerG[{{},{1/2-n}},{{0,1/2,1}, {}},s^2/4])/(2Sqrt[\[Pi]]),Re[n]<-(1/2)],{n,0, \[Infinity]},Assumptions -> R<= 1]*).The problem is that Mathematica can't calculate this Sum.Any ideas. $\endgroup$
    – Betatron
    May 5, 2018 at 11:14
  • 1
    $\begingroup$ @Betatron It is a completely different question. Why don't you ask in a separate thread? $\endgroup$
    – yarchik
    May 5, 2018 at 20:37

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.