2
$\begingroup$

I would like to solve an inequality of this type with parameters:

Reduce[(1 + 2b)Log[w - c] >= (1 + b)Log[w - 2*c] && 0 < b < 1 && 0 < c < w 
&& w > 0, c, Reals]

But I get: This system cannot be solved with the methods available to Reduce. The same goes for Solve. Am I missing something?

$\endgroup$
  • 3
    $\begingroup$ I'm afraid that you are not missing anything. It may just be that the methods currently implemented cannot tackle your kind of equation. You might be able to rewrite the equation in another form that Solve and Reduce can handle (although I have no suggestions on how to proceed there), but ultimately numerical solutions might be all that is available to you then. $\endgroup$ – MarcoB Apr 27 '18 at 17:43
  • 1
    $\begingroup$ You can use ApplySides(introduced in v 11.3) and manually simplify $\endgroup$ – Subho Apr 27 '18 at 18:12
  • 2
    $\begingroup$ I think you need c<w/2 don't you? ( not that it leads to a reduction..) $\endgroup$ – george2079 Apr 27 '18 at 18:32
  • $\begingroup$ @george2079 and all others that were adding this assumption bellow, that is correct c < w/2 $\endgroup$ – František Kaláb Apr 28 '18 at 15:25
5
$\begingroup$

I don't know if this is of much help but this is the best I could do:

SubtractSides[
 MultiplySides[
   ApplySides[
    Composition[PowerExpand, Power[#, 1/(1 + 2 b)] &, 
     Exp, (# /. x_*Log[y_] -> Log[y^x]) &], (1 + 2 b) Log[-c + 
        w] >= (1 + b) Log[-2 c + w]], 
   2] /. {2 (-c + w) -> u + w, (-2 c + w) -> u}, u + w]
(*0 >= -u + 2 u^((1 + b)/(1 + 2 b)) - w*)

where $u=-2 c+ w>0$

Now that $log$ has been eliminated, this inequality can possibly be further manipulated using some special mathematical techniques. I will think about that and update the post if I find any.

| improve this answer | |
$\endgroup$
  • $\begingroup$ I unfortunately have an older version of Mathematica but I will try it if I get an update! $\endgroup$ – František Kaláb Apr 28 '18 at 15:29
5
$\begingroup$

First, I believe that you need to add the condition $w>2c$ to keep $\log(w-2c)$ real. Given that $c>0$ then $(w-c)>(w-2c)>0$. Also, $(1+2b)>(1+b)$. Then you have $(1+2b)>(1+b)>0$ and $\log(w-c)>\log(w-2c)$. There are three cases

  1. $\log(w-c)>\log(w-2c)>0$ and your inequality is valid for all the values provided.

  2. $\log(w-c)>0$ but $\log(w-2c)<0$ and your inequality still holds for all the values provided.

  3. The remaining possibly non-trivial region is $0>\log(w-c)>\log(w-2c)$. There $(w-2c)<1$. There we can see that $1\leq\frac{1+2b}{1+b}\leq1.5$ for the values of $b$ that are of interest. Now, transforming your inequality (in the case $0>\log(w-c)>\log(w-2c)$) leads to $\frac{1+2b}{1+b}\leq\frac{\log(w-2c)}{\log(w-c)}$. Now DensityPlot or RegionPlot shows the region where $\frac{\log(w-2c)}{\log(w-c)}$ is between $1$ and $1.5$ and where $w>2c$.

        DensityPlot[UnitStep[w-2*c]*UnitStep[(Log[w-2*c]/Log[w-c]-1)]*UnitStep[-(1.5-Log[w-2*c]/Log[w-c])],{w,0,4},{c,0,2},PlotRange->All,Exclusions->None,PlotPoints->100]
    

White is the region that can fulfill the inequality for the third case. Horizontal axis is $w$ and vertical axis is $c$.

| improve this answer | |
$\endgroup$
5
$\begingroup$

It is not difficult to transform your inequality to a simpler one by defining $x=c/w$ satisfying $0<x<1$, $c<w/2$ to have real solutions, and $w-2c>1$:

$$w^b\frac{(1-x)^{2 b+1}}{(1-2 x)^{b+1}}\geq 1$$

Plotting the rational function for several values of $0<b<1$, we see clearly that $x<0.5$:

GraphicsRow@(Plot[
 Evaluate@
  Table[(1 - x)^(1 + 2 b)/(1 - 2 x)^(
   1 + b), {b, Range[1/10, 9/10, 1/10]}], {x, 0, #[[1]]}, 
 PlotRange -> #[[2]], GridLines -> {None, {1}}, 
 ImageSize -> 250] & /@ {{0.1, {0.75, 1.25}}, {0.49, {-1, 9}}})

enter image description here

We can inspect what happens when $x\rightarrow 0$ ($c\rightarrow 0$):

Limit[(1 - x)^(1 + 2 b)/(1 - 2 x)^(1 + b), x -> 0]

1

So it seems that the inequality is always fulfilled for $x=c/w<1/2$, and $w-2c>1$.

If $x=c/w$ satisfying $0<x<1$, $c<w/2$ to have real solutions, and $w-c<1$:

$$w^b\frac{(1-x)^{2 b+1}}{(1-2 x)^{b+1}}\leq 1$$

In this case as the rational function is monotonically increasing for different values of $b$, and $w\leq 1$, therefore, I presume some range for $c$ after solving numerically the above inequality given numerical values, and satisfying the initial conditions.

| improve this answer | |
$\endgroup$
  • $\begingroup$ Comments are not for extended discussion; this conversation has been moved to chat. $\endgroup$ – Kuba Apr 29 '18 at 11:05
4
$\begingroup$

You might find this useful, Reduce works for any rational b:

Simplify[Reduce[
   With[{b = 1/2}, (1 + 2 b) Log[w - c] >= (1 + b) Log[w - 2*c] && 
    0 < c < w/2 && w > 0], c, Reals], 
       Assumptions -> {w > 0, 0 < c < w/2, w > 0}]

The result is conditional involving root expressions.

enter image description here

note that we get w>1 regardless of b. (ie. the inequality is identically satisfied for 0<b<1,w>1,0<c<w/2)

here is a plot restricted to the non-trivial region 0<w<1

Plot[Evaluate[Table[
   Simplify[
     Reduce[(1 + 2 b) Log[w - c] >= (1 + b) Log[w - 2*c] && 
       0 < c < w/2 && 0 < w < 1, c, Reals], 
     Assumptions -> {w > 0, 0 < c < w/2, 0 < w < 1}][[2]], {b, 1/10, 
    1, 1/10}]], {w, 0, 1}]

enter image description here

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.