Display a polynomial in exponential generating function form

Question

Is there an easy way to have Mathematica display a polynomial in "exponential generating function" form? So, for example, rather than seeing $$1 + 2 x + 3 x^2 + 4 x^3$$ I would like to see $$1 + \frac{1}{1!} 2 x + \frac{1}{2!} 6 x^2 + \frac{1}{3!} 24 x^3$$ It would be especially nice if the output could also be captured in TeX format, as in TeXForm[].

Answer 1

You can easily do this by a simple replacement rule with the command Inactive:

(1 + 2 x + 3 x^2 + 4 x^3) /.  x_^n_ :> x^n Factorial[n]/Inactive[Factorial][n]

which yields the desired output

1+2 x+(6 x^2)/(2!)+(24 x^3)/(3!)

In addition, you can directly hit TeXForm without any problem and capture the desired form:

(1 + 2 x + 3 x^2 + 4 x^3) /. x_^n_ :> x^n Factorial[n]/Inactive[Factorial][n] // TeXForm

$\frac{24 x^3}{3!}+\frac{6 x^2}{2!}+2 x+1$

Answer 2

Here is a method that produces the appearance you requested. First, I define a wrapper that renders coefficients the way you want:

MakeBoxes[form[n_,r_], form_] ^:= TagBox[
    RowBox[{MakeBoxes[1/n!], MakeBoxes[r,form]}],
    #&,
    SyntaxForm->Power
]
MakeBoxes[form[0,r_], form_] := MakeBoxes[r, form]

For example:

form[2,6] //TeXForm

$\frac{1}{2!}6$

Then, I define a function to transform a SeriesData object (produced by the Series function):

toEGF[HoldPattern@SeriesData[a_,b_,c_,d_,e_,f_]] := Module[
    {orders, coeffs},

    orders = Range[d,d+Length[c]-1];
    coeffs = Replace[
        Transpose[{orders, orders! c}],
        {n_,r_}:>form[n,r]
        {1}
    ];
    SeriesData[a,b,foo,d,e,f]
]

Your example:

ser = Series[1 + 2x + 3x^2 + 4x^3, {x, 0, 3}];
ser //toEGF //TeXForm

$$1+\frac{1}{1!}2 x+\frac{1}{2!}6 x^2+\frac{1}{3!}24 x^3+O\left(x^4\right)$$