Im trying to find the Laurent expansion of the function

$$f(z):=\frac{a-b}{(z-a)(z-b)},\quad\text{for }0<|a|<|b|$$

around $z=0$ in the annulus defined by $A:=\{z\in\Bbb C:|a|<|z|<|b|\}$. What I did by now is trying to write a function for the coefficients defined by

$$c_n=\frac1{2\pi i}\int_{r\partial\Bbb D}f(z)z^{-n-1}\, dz,\quad n\in\Bbb Z,\, r\in(|a|,|b|)$$

thus I write

f[z_] := (a - b)/((z - a) (z - b))
c[k_, f_] := Integrate[With[{z = r E^(I t)}, f[z]/(2 Pi z^k)], {t, 0, 2 Pi}]

However Im not sure how to set $r\in(|a|,|b|)$ in the above code. Of course setting values for $a$ and $b$ I can get an expansion, but Im interested in the symbolic expansion in terms of $a$ and $b$ with the restrictions said above, that is, that $0<|a|<|b|$.

I had read almost all topics related to Laurent series but I dont find something to obtain symbolic expressions of these kind.

Some help will be appreciated, thank you.

  • $\begingroup$ Check this prior thread. $\endgroup$ Commented Apr 2, 2018 at 16:33
  • $\begingroup$ @Daniel Lichtblau: I tried that with no success (see my answer). $\endgroup$
    – user64494
    Commented Apr 2, 2018 at 16:39

4 Answers 4


A standard approach is to use a partial fraction decomposition, rearranged appropriately for the region of interest, that is, so that the corresponding infinite sum will converge.

In this case the pfd is as below.

In[209]:= Apart[(a - b)/((z - a) (z - b)), z]

(* Out[209]= 1/(-a + z) - 1/(-b + z) *)

Since |z|>|a| we write the first term as

(1/z)/(1 - a/z)

This expands to `1/z (1+a/z+(a/z)^2+(a/z)^3+...)

Since |z|<|b| the second terms should be written as

-(1/(-b) b)/(1 - z/b)

This expands to `(1/b) (1+z/b+(z/b)^2+(z/b)^3+...)

The Laurent expansion is simply the sum of these.

Here is an explicit way to get a finite truncation of specific order in the Wolfram Language. Expand the part involving a at infinity, and the part involving b at the origin, then sum.

Normal[Series[1/(-a + z), {z, Infinity, 3}]] + 
 Normal[Series[-(1/(-b + z)), {z, 0, 3}]]

(* Out[211]= 1/b + a^2/z^3 + a/z^2 + 1/z + z/b^2 + z^2/b^3 + z^3/b^4 *)

A more mechanical way of finding Laurant series can be done as follows

$Assumptions = {0 < a < r, 0 < r < b};
f[a_, b_, n_][z_] = 1/(2 \[Pi] I) (a - b)/((z - a) (z - b))  z^(-n - 1)
g[a_, b_, r_, n_][\[Theta]_] = 
f[a, b, n][ r Exp[I \[Theta]]] I r  Exp[ I \[Theta]] // Simplify
Table[ Integrate[ 
   g[a, b, r, n][\[Theta]], {\[Theta], 0, 2 \[Pi]}], {n, -10, 10}]
(* {a^9, a^8, a^7, a^6, a^5, a^4, a^3, a^2, a, 1, 1/b, 1/b^2, 1/b^3, \
 1/b^4, 1/b^5, 1/b^6, 1/b^7, 1/b^8, 1/b^9, 1/b^10, 1/b^11} *)

Unfortunately, Mathematica cannot evaluate the integral for arbitrary integers even with the assumption Assuming[ {n \[Element] Integers}, ....

This is basically a similar repetition of Laurent series expansion, which has been mentioned in this post several times.

  • $\begingroup$ This is not it. You additionally assume that $a$ and $b$ are positive real numbers. $\endgroup$
    – user64494
    Commented Apr 2, 2018 at 17:21
  • $\begingroup$ @user64494 Depending on what you want, it can be both wrong and right. As I mentioned already, Mathematica cannot handle the full generality of the problem, so restricting the problem to solvable subproblems is not necessarily a bad thing. But I totally understand your point and this point was not clear enough in the post. $\endgroup$
    – Sungmin
    Commented Apr 2, 2018 at 17:32

This is a variation on the theme of that topic.

With[{r = (Abs[a] + Abs[b])/2, n = 8}, 
 Table[FourierCoefficient[With[{z=r Exp[I t]},(a-b)/((z-a)*(z - b))], t, k ,Assumptions -> Abs[a] > 0 && Abs[a] < Abs[b]]/r^k, {k,-n,n}]]

$$\left\{0,0,0,0,0,0,0,0,\frac{1}{b}-\frac{1}{a},\frac{a^2-b^2}{a^2 b^2},\frac{a^3-b^3}{a^3 b^3},\frac{a^4-b^4}{a^4 b^4},\frac{a^5-b^5}{a^5 b^5},\frac{a^6-b^6}{a^6 b^6},\frac{a^7-b^7}{a^7 b^7},\frac{a^8-b^8}{a^8 b^8},\frac{a^9-b^9}{a^9 b^9}\right\} $$

  • $\begingroup$ there is something wrong there. In the defined annulus we have that $c_{-n}=a^{n-1}\neq 0$, however for $c_n$ your table seems correct. $\endgroup$
    – Masacroso
    Commented Apr 2, 2018 at 15:23
  • $\begingroup$ @Masacroso: Sorry, the result coinsides with the result of the Subho95's answer. Can you base your doubt? $\endgroup$
    – user64494
    Commented Apr 2, 2018 at 15:37
  • $\begingroup$ because $$c_{-n}=\frac1{2\pi i}\int_{r\partial\Bbb D}\frac{a-b}{(z-b)}z^{n-1}\cdot\frac1{z-a}\, dz=a^{n-1},\quad\text{for } n\ge 1$$ for $r\in(|a|,|b|)$. This is a consequence of $\frac{z^{n-1}}{z-b}$ being holomorphic in the described annulus. $\endgroup$
    – Masacroso
    Commented Apr 2, 2018 at 15:42
  • $\begingroup$ @Masacroso: You are right. I have to think about that. The assumptions on $a$ and $b$ in the FourierCoefficient command change nothing in the output. $\endgroup$
    – user64494
    Commented Apr 2, 2018 at 16:22
  • $\begingroup$ @Masacroso: Likely a bug in FourierCoefficient or a gap in the help to this command. $\endgroup$
    – user64494
    Commented Apr 2, 2018 at 17:55

Series with Assumptions option is an easy way:

In[11]:= f[z_] := (a - b)/((z - a) (z - b))

In[12]:= Series[f[z], {z, 0, 10}, 
  Assumptions -> (Abs[a] < Abs[z] < Abs[b])] // Normal

Out[12]= (a - b)/(a b) + ((a - b) (a + b) z)/(
 a^2 b^2) + ((a - b) (a^2 + a b + b^2) z^2)/(
 a^3 b^3) + ((a - b) (a^3 + a^2 b + a b^2 + b^3) z^3)/(
 a^4 b^4) + (1/(a b^5) + 1/(a^2 b^4) + 1/(a^3 b^3) + 1/(a^4 b^2) + 1/(
    a^5 b)) (a - b) z^4 + (1/(a b^6) + 1/(a^2 b^5) + 1/(a^3 b^4) + 1/(
    a^4 b^3) + 1/(a^5 b^2) + 1/(a^6 b)) (a - b) z^5 + (1/(a b^7) + 1/(
    a^2 b^6) + 1/(a^3 b^5) + 1/(a^4 b^4) + 1/(a^5 b^3) + 1/(
    a^6 b^2) + 1/(a^7 b)) (a - b) z^6 + (1/(a b^8) + 1/(a^2 b^7) + 1/(
    a^3 b^6) + 1/(a^4 b^5) + 1/(a^5 b^4) + 1/(a^6 b^3) + 1/(
    a^7 b^2) + 1/(a^8 b)) (a - b) z^7 + (1/(a b^9) + 1/(a^2 b^8) + 1/(
    a^3 b^7) + 1/(a^4 b^6) + 1/(a^5 b^5) + 1/(a^6 b^4) + 1/(
    a^7 b^3) + 1/(a^8 b^2) + 1/(a^9 b)) (a - b) z^8 + (1/(a b^10) + 
    1/(a^2 b^9) + 1/(a^3 b^8) + 1/(a^4 b^7) + 1/(a^5 b^6) + 1/(
    a^6 b^5) + 1/(a^7 b^4) + 1/(a^8 b^3) + 1/(a^9 b^2) + 1/(
    a^10 b)) (a - b) z^9 + (1/(a b^11) + 1/(a^2 b^10) + 1/(a^3 b^9) + 
    1/(a^4 b^8) + 1/(a^5 b^7) + 1/(a^6 b^6) + 1/(a^7 b^5) + 1/(
    a^8 b^4) + 1/(a^9 b^3) + 1/(a^10 b^2) + 1/(a^11 b)) (a - b) z^10
  • $\begingroup$ but this is not a Laurent expansion of the function in the annulus, this is just the Taylor expansion of the function $\endgroup$
    – Masacroso
    Commented Apr 2, 2018 at 15:36
  • $\begingroup$ Series does give the Laurent expansion. For your example, there is simply no negative power term in the Laurent expansion. $\endgroup$
    – Subho
    Commented Apr 2, 2018 at 15:43
  • $\begingroup$ this is not correct, the negative coefficients are $c_{-n}=a^{n-1}$. See the comment that I give in the other answer. $\endgroup$
    – Masacroso
    Commented Apr 2, 2018 at 15:44
  • 1
    $\begingroup$ The assumptions are not compatible with expanding at the origin. Which can mess things up in an internal use of Refine inside Series. $\endgroup$ Commented Apr 2, 2018 at 16:27
  • $\begingroup$ @Masacroso Yeah, you are right $\endgroup$
    – Subho
    Commented Apr 2, 2018 at 16:50

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.