2
$\begingroup$

I'm trying to plot two parametric graphs as follows:

   alpha3[t_] := {Sin[2t]Cos[t],Sin[2t]Sin[t]}
   evoluta[t_] := alpha3[t]+(1/kappa[alpha3][t]) normal[alpha3][t]
   graph1 = ParametricPlot[alpha3[t]//Evaluate,{t,-2Pi,2Pi},PlotStyle->{{PlotRange -> 1}}]
   graph2 = ParametricPlot[evoluta[t]//Evaluate,{t,-2Pi,2Pi},PlotStyle->{{RGBColor[0.8,0.2,0.2],PlotRange ->1}}]
   Show[graph1,graph2]

The result obtained is:

enter image description here

I would like that the whole plot appears on the screen, however, PlotRange->All is not working for me?

How can I do so?

Extra (code for drawing evolute)

tangent[alpha_][t_]:=D[alpha[u],u]/Simplify[Factor[D[alpha[u],u].D[alpha[u],u]]]^(1/2) /. u->t
J:={{0,-1},{1,0}}
normal[alpha_][t_]:=J.tangent[alpha][t]
kappa[alpha_][t_]:=Det[{D[alpha[u],u],D[alpha[u],{u,2}]}]/
Simplify[D[alpha[u],u].D[alpha[u],u]]^(3/2)/.u->t
| improve this question | |
$\endgroup$
  • $\begingroup$ Try ParametricPlot[{alpha3[t], evoluta[t]} // Evaluate, {t, -2 Pi, 2 Pi}, PlotRange -> All, PlotStyle -> {{}, Directive[RGBColor[0.8, 0.2, 0.2], Thick]}]. $\endgroup$ – J. M.'s technical difficulties♦ Mar 30 '18 at 0:32
  • $\begingroup$ ok, even ParametricPlot[ {alpha3[t],evoluta[t]}//Evaluate,{t,-2 Pi,2 Pi}] works apparently $\endgroup$ – Rodrigo Mar 30 '18 at 0:36
  • $\begingroup$ Yes; I added PlotStyle just to show how to change styles for a specific curve. Remember to use Directive[] if you want to apply more than one style (e.g. color and thickness at the same time). $\endgroup$ – J. M.'s technical difficulties♦ Mar 30 '18 at 0:38
  • $\begingroup$ You did not include the definitions of kappa or normal. Questions should include executable code. $\endgroup$ – Bob Hanlon Mar 30 '18 at 1:34
  • $\begingroup$ @BobHanlon I added the missing details, thanks $\endgroup$ – Rodrigo Mar 30 '18 at 10:09
3
$\begingroup$

Since the OP has forgotten to include the sundry definitions, let me instead present a compact way to render a curve and its evolute:

f[t_] := {Sin[2 t] Cos[t], Sin[2 t] Sin[t]};

{{kappa[t_]}, {tangent[t_], normal[t_]}} = FrenetSerretSystem[f[t], t];

ParametricPlot[{f[t], f[t] + normal[t]/kappa[t]}, {t, 0, 2 π}]

quadrifolium and its evolute

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.