1
$\begingroup$

Plot all three; the function, its derivative and its tangent line at a given point. Then, find the second and third derivative of the function.

f(x)= x^(3)-2x, x= -1

I know its something like this, but I kept getting the wrong answer or error messages.

f[x_] := [[x^(3)-2x, x],{x-> -1}]
f'[]
f''[]
f'''[]
Plot[{f[x],f'[x],f''[x], f'''[x]},{x},PlotLegends->"Expressions"]

Not sure about the tangent line

$\endgroup$
  • $\begingroup$ Have you seen this? $\endgroup$ – J. M. is away Mar 26 '18 at 23:40
  • $\begingroup$ I tried making some sense but its looks confusing. All i know is how to find the slope not the tangent line: ReplaceAll[D[x^3 - 2 x, x], {x -> -1}] I have have issues with the Plotting all the equation in one graph. $\endgroup$ – Robbie Mar 26 '18 at 23:54
  • $\begingroup$ i figured out the tangent line equation, im getting errors plotting the graph. $\endgroup$ – Robbie Mar 27 '18 at 0:12
3
$\begingroup$

I like David Stork's answer, but I also think an answer more focused on the specific example give by the OP might be helpful.

The given function

f[x_] := x^3 - 2 x

Its 1st derivative

d1F[x_] = f'[x]

-2 + 3 x^2

Note that I use Set ( = ), not SetDelayed ( := ), because I want the d1F to the specific derivative of x^3 - 2 x and not just a synonym for f'[x].

The tangent line

At a given point, say x0, the tangent line is the line passing through {x0, f[x0]} having slope f'[x0] and is given by

f[x0] + f'[x0] (x - x0)

That the this expression is a line is obvious because it is a linear function of x. That it passes through {x0, f[x0]} is trivial because when x is set to x0, the 2nd term is 0. Further, since a line's slope is the multiplier of its independent variable and x is multiplied by f'[x0], the line has the required slope. So a function giving the tangent line of f when x == x0 can be defined by

tangentF[x_, x0_] = f[x0] + f'[x0] (x - x0) // Simplify

-2 x0^3 + x (-2 + 3 x0^2)

Again, I use Set ( = ), not SetDelayed ( := ), because I want the tangent function to be specific to f.

Now we have everything we need to make the plot.

With[{x0 = -1},
  Plot[{f[x], d1F[x], tangentF[x, x0]}, {x, -2, 1},
    Epilog -> {Red, PointSize[Large], Point[{x0, f[x0]}]},
    AspectRatio -> 1,
    PlotRange -> {-4, 4},
    PlotLegends -> {"Function", "Derivative", "Tangent Line"}]]

plot

As for the two higher derivatives, they are given by

f''[x]

6 x

and

f'''[x]

6

$\endgroup$
  • $\begingroup$ That’s perfect ! I think this explains more throughly since I’m still a noob . I really appreciate your help. $\endgroup$ – Robbie Mar 27 '18 at 2:29
2
$\begingroup$
    ff[myfun_, x_, x0_] := 
 Plot[{Evaluate[myfun@x], 
       Evaluate[myfun'@x], 
       Evaluate[myfun''@x], 
       Evaluate[myfun'''@x],
       Evaluate[x myfun'[x0] + myfun[x0] - x0 myfun'[x0]]}, 
  {x, 0, 4},
  PlotLegends -> "Expressions",
  PlotStyle -> {Red, Green, Blue, Orange, {Dashed, Purple}},
  Epilog -> {PointSize[0.02], Red, Point[{x0, myfun@x0}]}];

ff[Sin[#] &, x, 1]

enter image description here

or

ff[Sin[#^2/5] &, x, 1]

enter image description here

$\endgroup$
  • $\begingroup$ Thank you David . $\endgroup$ – Robbie Mar 27 '18 at 2:30

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.