0
$\begingroup$

I have this dynamical system

StreamPlot[{2 x - 8/5 x^2 - x*y, 5/2 y - y^2 - 2 x*y}, {x, 0, 2}, {y, -.5, .5}]

There is a stable fixed point at (1.25, 0) (I checked through the linearized matrix). It seems to be a very weak stable fixed point. However, I have a hard time seeing any steamline going directly to that fixed point. Can anyone please help me create one solution curve (make it in red please) that goes from any positive initial conditions x and y (let's just pick x = 10, y = .05) to the fixed point (1.25, 0)? Thank you so much!

$\endgroup$
  • 1
    $\begingroup$ It's not stable. (The Jacobian is singular, so you have to go to the second-order approximation.) $\endgroup$ – Michael E2 Mar 11 '18 at 0:02
  • $\begingroup$ @MichaelE2 Yes, it seems that the Jacobian is indeed singular. How do I do the second-order approximation though? Please help! You can answer that here, math.stackexchange.com/questions/2684568/… $\endgroup$ – Phu Nguyen Mar 11 '18 at 1:21
  • $\begingroup$ The easiest way to analyze the stability might be the nullclines: RegionPlot[{2 x - 8/5 x^2 - x*y < 0, 5/2 y - y^2 - 2 x*y < 0}, {x, 1.22, 1.28}, {y, -.02, .02}] $\endgroup$ – Michael E2 Mar 11 '18 at 4:20
2
$\begingroup$

Something like this?

 f[{x_, y_}] := {2 x - 8/5 x^2 - x y, 5/2 y - y^2 - 2 x y}
 field = StreamPlot[f[{x, y}], {x, 0, 2}, {y, -.5, .5}];
 {xsoln, ysoln} = NDSolveValue[{{x'[t], y'[t]} == f[{x[t], y[t]}], 
      x[0] == 10, y[0] == 0.5}, {x, y}, {t, 0, 10}];
 curve = ParametricPlot[{xsoln[t], ysoln[t]}, {t, 0, 10}, 
      PlotStyle -> {Red, Thickness[Medium]}, PlotRange -> All];
 pt = {1.25, 0};
 Show[{field, curve, Graphics[{Black, PointSize[Large], Point[pt]}]}]

Solution curve in stream

For the particular solution curve, I chose an initial condition a bit further away from the x-axis so it would display better.

$\endgroup$
  • $\begingroup$ Yes, that is what I want. Thank you! $\endgroup$ – Phu Nguyen Mar 11 '18 at 1:14

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.