1
$\begingroup$

The lemniscate of Bernoulli is a curve in the complex plane given by $|z^2-1|=1$ that has the shape of $\infty.$:

lemniscate

This is a special case of the Cassini ovals that has the form $|z^2-1|=r^2$ for $r\in\Bbb{R}.$ The important property of the lemniscate of Bernoulli is that it passes through the critical point of the polynomial $P(z)=z^2-1.$

I am trying to see the generalization of this notion for higher degree polynomials.

For example, consider the polynomial $z^3-z.$ I assume the corresponding Bernoulli lemniscate type curve is a lemniscate with three holes (This may not be the correct terminology, but hope you can visualize it).

Also (I assume) the corresponding lemniscate curve of $z^3-1$ is a three leaved rose.

But for complicated polynomials like $z(z-1)(z-3)(z-6)$, we may have more than one possible lemniscate structures.

Now, I am trying to visualize these possible lemniscate structures graphically. Is there any easy way to do this using Mathematica?

Improve this question
$\endgroup$
7
  • 1
    $\begingroup$ To broden the context one can draw a lemniscate using ContourPlot for the Weierstrass elliptic function, see e.g. Integrate yields complex value, while after variable transformation the result is real. Bug?. See also the lemniscatic case in Weierstrass Elliptic Function. $\endgroup$
    – Artes
    Mar 9, 2018 at 19:22
  • 1
    $\begingroup$ It is not clear if you are looking for something like this: Manipulate[ z = x + I y; ContourPlot[Abs[z^3 - z] == r^2, {x, -2, 2}, {y, -2, 2}], {{r, 1/2}, 0.1, 2}]. I upvoted your question since I find it an interesting topic, nonetheless I'd prefer to clarify and underline what is your problem since I cannot see a piece of Mathematica code. $\endgroup$
    – Artes
    Mar 9, 2018 at 19:45
  • $\begingroup$ @Artes: This is very closed to what I am looking for. But more specifically I need only the pictures of curves with self intersections. $\endgroup$
    – Bumblebee
    Mar 9, 2018 at 20:12
  • $\begingroup$ I don't understand what you need here either; why wouldn't the ContourPlot[] approach suffice here? Also, have you seen this? $\endgroup$
    – J. M.'s eventual burnout ♦
    Mar 9, 2018 at 22:38
  • 1
    $\begingroup$ To summarize: given a set of points, you want to find values of $r$ such that the resulting Cassinian curves have nodes? $\endgroup$
    – J. M.'s eventual burnout ♦
    Mar 10, 2018 at 21:58

1 Answer 1

Reset to default
3
$\begingroup$

I'll use $|z(z-1)(z-3)(z-6)|^2=r$ as an example for this answer. To find crunodes, we refer to the condition for a singular point to be a crunode:

…a crunode of the curve is a singularity of the function $f$, where both partial derivatives $\partial f \over \partial x$ and $\partial f \over \partial y$ vanish. Further the Hessian matrix of second derivatives will have both positive and negative eigenvalues.

Thus:

expr = With[{z = x + I y},
            ComplexExpand[Abs[z (z - 1) (z - 3) (z - 6)]^2,
                          TargetFunctions -> {Re, Im}] - r];

grad = D[expr, {{x, y}}]; hess = D[expr, {{x, y}, 2}];

sols = Solve[Thread[grad == 0], {x, y}, Reals];
sel = Pick[sols, Negative[Det[hess] /. sols]]
   {{x -> Root[-9 + 27 #1 - 15 #1^2 + 2 #1^3 &, 1], y -> 0},
    {x -> Root[-9 + 27 #1 - 15 #1^2 + 2 #1^3 &, 2], y -> 0},
    {x -> Root[-9 + 27 #1 - 15 #1^2 + 2 #1^3 &, 3], y -> 0}}

This yields three points that can possibly be crunodes, depending on the value of r. Now, we do this:

vals = FullSimplify[r /. First[Solve[#, r, Reals]]] & /@ (expr == 0 /. sel)
   {Root[-332150625 + 32240754 #1 - 430353 #1^2 + 256 #1^3 &, 1],
    Root[-332150625 + 32240754 #1 - 430353 #1^2 + 256 #1^3 &, 2],
    Root[-332150625 + 32240754 #1 - 430353 #1^2 + 256 #1^3 &, 3]}

Visualize the corresponding curves:

Table[ContourPlot[With[{z = x + I y}, Abs[z (z - 1) (z - 3) (z - 6)]^2] == r,
                  {x, -8, 8}, {y, -8, 8}, 
                  PlotLabel -> "r=" <> ToString[NumberForm[N[r], 6]]],
      {r, vals}] // GraphicsRow

cases with nodes

Improve this answer
$\endgroup$
3
  • $\begingroup$ Thank you very much for your answer. I'll ask if I found any unclear thing. $\endgroup$
    – Bumblebee
    Mar 13, 2018 at 22:54
  • $\begingroup$ Today I played with this and realized that it does not work with polynomials like $z^4-1.$ What did I miss here? $\endgroup$
    – Bumblebee
    Mar 25, 2018 at 21:11
  • $\begingroup$ If you tried the evaluation up to sel, you'll notice that the result of sel is an empty list; i.e., no saddle points were found. $\endgroup$
    – J. M.'s eventual burnout ♦
    Mar 26, 2018 at 0:38

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.