How to double (or triple) each element of equation?

Question

x^2/3+y^2/9==1
(0.5x)^2/3+(0.5*y)^2/9==1

Looks at above two equation,I multiply 0.5 to each element of second equation,which means when plotting, each point x,y will become 2x,2y.I use this method to enlarge plotting object .

But as to complex equation like y^4+2y^2*x-3xy+7x^3==176.984 or r==Sqrt[Sin[2 θ]],I want to ask how to use mathematica built in function to make it easy?

Answer 1

Given an equation $F(x,y)=0$ and a transformation $t(x,y)$ that, say, scales points by $2$, then to scale the graph of $F=0$, one applies the inverse transformation and plots $F(t^{-1}(x,y))=0$.

transformEQ[t_, vars_, eq_] :=
  Function[vars, eq] @@ InverseFunction[t]@vars;

equation = y^4 + 2 y^2*x - 3 x y + 7 x^3 == 176.984;
transformEQ[ScalingTransform[{2, 2}], {x, y}, equation]
(*  (7 x^3)/8 - (3 x y)/4 + (x y^2)/4 + y^4/16 == 176.984  *)

In polar coordinates, or in another coordinate system, one either converts the coordinates or the transformation $t$. Since transformations in cartesian coordinates are built into Mathematica, the first point of view seems convenient.

transformEQ[t_, vars_, eq_, "Polar"] :=
  Function[vars, eq] @@ Simplify[       (* simplifying is optional *)
    Composition[
      ToPolarCoordinates,
      InverseFunction@t,
      FromPolarCoordinates
      ][vars],
    {First@vars > 0, -Pi < Last@vars < Pi}]; (* match the branch cuts of ArcTan[x, y] *)

polar = r == Sqrt[Sin[2 θ]];
transformEQ[ScalingTransform[{2, 2}], {r, θ}, polar, "Polar"]
(*  r/2 == Sqrt[Sin[2 θ]]  *)

Note: The assumption on the angle generally produces the correct formula, sometimes even when the condition is not met. If a transformed equation seems incorrect, then I would check this first.

This could be extended to other coordinate systems with CoordinateTransformData.

Answer 2

You can use ReplaceAll (/.) to replace each instance of x with .5 x and so on:

equation = y^4 + 2 y^2*x - 3 x y + 7 x^3 < 176.984;
scaled = equation /. {x -> 0.5 x, y -> 0.5 y}

0.875 x^3 - 0.75 x y + 0.25 x y^2 + 0.0625 y^4 == 176.984

RegionPlot[{equation, scaled}, {x, -10, 10}, {y, -10, 10}, 
 PlotLegends -> {"equation", "scaled"}]

Alternatively, if you have many variables and you don't want to write a rule for each one, you can use Alternatives (|) to match a set of symbols in one rule:

equation /. var : (x | y | z | r) :> 0.5 var

Answer 3

Change your variables: ./{x->0.5x,y->0.5y}

Answer 4

Edit: I entirely ignored the subtlety of what should happen in polar coordinates. See OP's comment.

---

A version of what others have suggested that find the variables for you.

_{(There's a lot of machinery in this answer -- tbh, writing it was largely an exercise in using such machinery for me. As such, please do ask me about anything that's too much to absorb with a quick look at the docs.)}

Definition

ClearAll[scaleLHS]
Options[scaleLHS] = {"variables" -> Automatic};

scaleLHS[a_ == b_, scaleFactor_, OptionsPattern[] ] :=
    Module[{vars = OptionValue@"variables"},
        vars = Switch[vars
            , Automatic, Variables@a
            , _Symbol, {vars}
            , _Function, vars[a]
            , _, vars
        ];
        (a /. Thread[vars -> scaleFactor*vars]) == b
    ]

(* thread over lists of equations *)
scaleLHS[eqList_List, args__] := scaleLHS[#, args] & /@ eqList

(* operator form, because these can be incredibly useful *)
scaleLHS[scaleFactor : (_Symbol | _?NumericQ), args___?(MatchQ[_Rule | {___Rule}])][eq_] := 
    scaleLHS[eq, scaleFactor, args]

Usage

The variables can often be discovered for you automatically. This works whenever Variables returns the right variables:

scaleLHS[c] @ {x^2/3 + y^2/9 == 1, y^4 + 2 y^2*x - 3 x y + 7 x^3 == 176.984}

{(c^2 x^2)/3 + (c^2 y^2)/9 == 1, 7 c^3 x^3 - 3 c^2 x y + 2 c^3 x y^2 + c^4 y^4 == 176.984}

Variables treats the entire trig function as a variable, so you need to manually specify θ :

scaleLHS[Sqrt[Sin[2 θ]] == r, c, "vars" -> θ]

Sqrt[Sin[2 c θ]] == r

Possible improvements

• Define an analagous function scaleRHS
  • Until then, just do Reverse@scaleLHS[Reverse@equation, scaleFactor]
• Allow different variables to be scaled differently
• Deal with e.g. polar coordinates in the way OP would like
  • Probably looks like adding an additional option (e.g., "coordinates" -> "Polar"), and some extra work