# How to move object when plotting without axes change?

ContourPlot[
Power[(x), 3/2] - Power[1.65, 0.5]*(x) + ((y))^2 ==
0, {x, -20, 20}, {y, -20, 20}, PlotPoints -> 100,
MaxRecursion -> 1]


Then I need to rotate and move this object to the below position I know RotationMatrixcan rotate,but how to move object with mathematica function?

• The parameter b is not defined in your code. I assume b = 1/3? – JEM_Mosig Mar 7 '18 at 4:23
• @JEM_Mosig,b just make plot bigger, I edited question. – kittygirl Mar 7 '18 at 4:27

It is more clear if we rewrite your code as follows:

b = 1/3;
f[{x_, y_}] := Power[b*(x), 3/2] - Power[1.65, 0.5]*b*(x) + (b*(y))^2;

ContourPlot[f[{x, y}] == 0, {x, -20, 20}, {y, -20, 20},
PlotPoints -> 100,
MaxRecursion -> 1
]


This produces your original figure, but we have defined an explicit function f, for convenience. Now we can define the geometric transformation that rotates your figure about {0,0} by 105° and then moves it by {-10, 5} in the (x,y) plane.

tf = RotationTransform[105 Degree, {0, 0}]@*TranslationTransform[-{-10, 5}];


Now

ContourPlot[f[tf@{x, y}] == 0, {x, -20, 20}, {y, -20, 20},
PlotPoints -> 100,
MaxRecursion -> 1
]


• @kitty, what version are you using? If you are using a version older than 10, try this instead: ContourPlot[f[AffineTransform[{RotationMatrix[105 °], {10, -5}}] @ {x, y}] == 0 // Evaluate, {x, -20, 20}, {y, -20, 20}, PlotPoints -> 100, MaxRecursion -> 1] – J. M.'s technical difficulties Mar 7 '18 at 5:36
• @J.M.version 11.2.I guess something wrong in your f[{x_, y_}] := Power[b*(x), 3/2] - Power[1.65, 0.5]*b*(x) + (b*(y))^2; – kittygirl Mar 7 '18 at 7:03
• Did you define b = 1/3? I just copied your code there. – JEM_Mosig Mar 7 '18 at 22:30