6
$\begingroup$

I need to plot the Reuleaux triangle in rectangular coordinates.

Reuleaux triangle

I am not sure if there's a Reuleaux triangle equation. If yes, I can plot it by ContourPlot.

I saw link but I just need curve of Reuleaux triangle.

What's the best way to plot a Reuleaux triangle?

Improve this question
$\endgroup$
1
  • 1
    $\begingroup$ The Reuleaux triangle has sharp corners, so ContourPlot would have problems to draw that. $\endgroup$
    – Henrik Schumacher
    Mar 5, 2018 at 9:12

2 Answers 2

Reset to default
7
$\begingroup$

A long time ago, I derived parametric equations for Reuleaux polygons.

Specializing the formulae in that post to the triangle case, we have

ParametricPlot[{(Sqrt[3] Cos[π/6 (2 SawtoothWave[u] - 1)] - 1) Cos[π/3 (2 Floor[u] + 1)] -
                Sqrt[3] Sin[π/6 (2 SawtoothWave[u] - 1)] Sin[π/3 (2 Floor[u] + 1)],
                Sqrt[3] Cos[π/3 (2 Floor[u] + 1)] Sin[π/6 (2 SawtoothWave[u] - 1)] +
                (Sqrt[3] Cos[π/6 (2 SawtoothWave[u] - 1)] - 1) Sin[π/3 (2 Floor[u] + 1)]},
               {u, 0, 3}]

Reuleaux triangle

After some prompting by Jens, I tried looking again for a polar representation of the Reuleaux triangle. I finally managed to find one, but it is not very pretty:

PolarPlot[Cos[Mod[θ, 2 π/3, 2 π/3]] + Sqrt[2 + Cos[Mod[θ, 2 π/3, 2 π/3]]^2],
          {θ, 0, 2 π}]

Reuleaux triangle

Improve this answer
$\endgroup$
2
  • $\begingroup$ I'd be curious if there's a simple form that could be used with PolarPlot. Probably not... but maybe you've thought about it. $\endgroup$
    – Jens
    Mar 5, 2018 at 23:16
  • 1
    $\begingroup$ @Jens, I haven't found one, but definitely not for lack of trying. $\endgroup$
    – J. M.'s eventual burnout ♦
    Mar 5, 2018 at 23:19
5
$\begingroup$

Not sure if the best but here is one way:

RegionIntersection @@ (Disk /@ CirclePoints[1/Sqrt[3], 3]) // 
RegionBoundary // 
Region

enter image description here

Improve this answer
$\endgroup$
2
  • $\begingroup$ I am impressed with the simplicity of your solution ! $\endgroup$
    – yarchik
    Mar 5, 2018 at 9:30
  • 2
    $\begingroup$ @yarchik thanks, yes one can get lazy with Mathematica $\endgroup$
    – Kuba ♦
    Mar 5, 2018 at 9:40

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.