How to superimpose a curve fit on top of a TimeSeries plot?

Question

This is a remarkably simple question for which I was not able to find an answer in the documentation.

For concreteness, suppose that we have some time series data, such as this (example taken straight from the Mathematica documentation):

ts = TimeSeries[FinancialData["MSFT", "Jan. 1, 2008"]];

...which we can plot with

DateListPlot[ts]

...to get this

Now, I can generate a linear fit to this data (which will be pretty lame, of course) with

fit = FindFit[ts, a + b t, {a, b}, t]

{a -> -526.325, b -> 1.58402*10^-7}

My question is: how do I superimpose the line corresponding to this linear approximation on top of the DateListPlot shown above?

Is there a simple way to do this?

NB: In case it matters, I'm interested in solutions that can be extrapolated beyond the data's original range. For example, I'd like to superimpose the line fit above over the curve shown below, so that the domain of the fit extends over all of the horizontal PlotRange (through the end of 2020):

DateListPlot[ts, PlotRange -> {{Automatic, {2020, 12, 31}}, {0, 150}}]

Answer 1

(* set end date *)
With[{tend = {2020, 12, 31}},
  (* timings *)
  With[{times = ts["Times"], extension = Rest[DateRange[ts["LastTime"], AbsoluteTime[tend]]]},
    (* localize vars *)
    Block[{lmf, abst, est, ext, y, t, lts, xlts},
      (* linear fit *) 
      lmf = LinearModelFit[ts, abst, abst];
      (* linear est *)
      est = lmf["Response"] - lmf["FitResiduals"];
      (* linear ts over sample *)
      lts = TimeSeries[est, {times}, DateFunction :> (DateList[#] &)];
      (* out-of-sample est *)
      ext = lmf["Function"] /@ extension;
      (* out-of-sample ts *)
      xlts = TimeSeries[ext, {extension}, DateFunction :> (DateList[#] &)];
      (* prepare output plot *)
      DateListPlot[
        {ts, lts, xlts},
        PlotRange -> {{Automatic, tend}, {0, 150}},
        PlotLegends -> Placed[
          {TimeSeries, LinearModelFit, Row[{LinearModelFit , , out , , of, , sample}]}, Below]
       ]
     ]
   ]
 ]

Answer 2

This might work. It is important to put DateListPlot first into Show in order to get appropriate coordinate axes.

ts = TimeSeries[FinancialData["MSFT", "Jan. 1, 2008"]];
fit = FindFit[ts, a + b t, {a, b}, t];
f = t \[Function] Evaluate[ b t + a /. fit];
ts2 = Transpose[{ts["Times"], Map[f, ts["Times"]]}];
Show[
 DateListPlot[ts],
 ListLinePlot[ts2, PlotStyle -> ColorData[97][2]]
 ]

Answer 3

You can just use the fit as an epilog if you appropriately extract the times from your data. First define fit as a function:

fit[t_] = a + b t /. FindFit[ts, a + b t, {a, b}, t];

and then make a line as an epilog to your DateListPlot:

Module[{firstlast = ts["Times"][[{1, -1}]]}, 
 DateListPlot[ts, Epilog -> Line[{#, fit@#} & /@ firstlast]
 ]
]

Answer 4

I was also trying to do something similar, but in Mathematica 12, the above code doesn't work. It gives you this error: "FindFit::ivar: Dataset [<<4>>] is not a valid variable." I'm very new to Mathematica and didn't find that particularly helpful.

To make it work you have to enable the "Legacy" switch when you get the data:

 ts = TimeSeries[FinancialData["MSFT", "Jan. 1, 2008", Method -> "Legacy"]];

Once you do this, the rest of it works as before.