Dynamic triggered but renders the same content

Question

Documentation bug introduced in V10 or eralier and persisting through V11.3

It is a documentation bug because the undocumented optimization method by FE makes major assumptions.

The example is not artificial as it is about basic refreshing of Dynamic object 'on demand'.

---

trigger = True;

panel[] := DynamicModule[{x}, Framed@Dynamic[x], 
   Initialization :> (x = RandomReal[])];

Column[{
  Button["redo", trigger = ! trigger, Method -> "Queued"],
  Dynamic@trigger,
  Dynamic[trigger; panel[], TrackedSymbols :> {trigger}],
  Dynamic[trigger; {RandomReal[], panel[]}, TrackedSymbols :> {trigger}]      
}]

As you can see Dynamic[trigger; panel[], TrackedSymbols :> {trigger}] is not displayed correctly after button action.

What is weirder, if you check with Echo, e.g:

Dynamic[Echo@trigger; panel[], TrackedSymbols :> {trigger}]

you will see that trigger is echoed while the display does not change.

Why does it happen? Is this a bug?

This piece of code shows a use case of updating a Dynamic on demand, what is the safe way to achieve this in general?

---

Similar problems with Dynamic not updating properly:

What is the difference between Dynamic[x] and Dynamic[ h[x] ] for DynamicModule variables?

Why is PaneSelector caching nested Dynamics and how to switch it off?

Dynamic not responding to Refresh TrackedSymbols

---

reproduced on Win10 V10.4 / V11.2

[CASE:4017880] was created

Answer 1

There is an optimization in the front end that's catching this case. Specifically, when the FE requests the evaluation of the Dynamic, it checks to see if the resulting expression that came back is different from the previous expression. If it's the same, then it does not destroy and recreate the boxes.

Since this is a typeset DynamicBox, it's sending a ToBoxes evaluation. The result of that evaluation is:

DynamicModuleBox[{x$$}, 
 FrameBox[DynamicBox[ToBoxes[x$$, StandardForm]], 
  StripOnInput -> False], Initialization :> (x$$ = RandomReal[]), 
 DynamicModuleValues :> {}]

The fact that trigger changed did cause it to re-evaluate, but when it evaluated, it returned exactly the same thing, so the front end optimization kicks in and it decides to do nothing. Is this correct? It's not documented, but frankly that's just because it never occurred to me that this would be an issue. If this must rise above the level of undefined behavior, then I'd be inclined to keep the current behavior and document it.

Working around this is simply a matter of ensuring that a different expression is actually returned. For example, this would do it:

trigger = True;

panel[t_] := 
  DynamicModule[{x}, Framed@Dynamic[x], 
   Initialization :> (t; x = RandomReal[])];

Column[{Button["redo", trigger = ! trigger, Method -> "Queued"], 
  Dynamic[panel[trigger], TrackedSymbols :> {trigger}]}]

Here, I've added a reference to trigger which gets passed into panel[] and embedded in the DynamicModule initialization. Then, instead of the resulting ToBoxes expression simply including Initialization :> (x$$ = RandomReal[]), it will now include Initialization :> (False; ...) or Initialization :> (True; ...), and the fact that it toggles back and forth will defeat the front end optimization.