How can I check if a function remains unevaluated?

Question

I am trying to check if a function remains unevaluated.

For example

$$\int \ln ^5(3 x) \sec (3 x) \, dx$$

remains unevaluated in Mathematica, instead $$\int \sec (3 x) \, dx$$ doesn't.

What I tried is

func = Log[3 x]^5*Sec[3 x];
IntFunc = With[{function = func}, HoldForm[Integrate[function, x]]];
SameQ[IntFunc,ReleaseHold[IntFunc]]

which returns False. I also tried

Equal[IntFunc,ReleaseHold[IntFunc]]

which remains unevaluated. I am pretty sure that this has to do with Hold $(*)$ but I don't understand how to fix this. Is there a way to test if a function remains unevaluatd? In other words, get True if it's unevaluated and False if it's evaluated?

---

$(*)$ Because when I try:

SameQ[Integrate[func, x], ReleaseHold[IntFunc]]

it returns True.

Answer 1

check if a function remains unevaluated.

Why not just check the head?

func = Log[3 x]^5*Sec[3 x];
result = Integrate[func, x]

If[Head[result] === Integrate,
 Print["Opps"],
 Print["it worked"]
 ]

Update for comment

Use this to check if result contains Integrate anywhere

func = 20* Log[3 x]^5*Sec[3 x];
result = Integrate[func, x]

If[FreeQ[result, Integrate, Infinity],
 Print["it worked"],
 Print["Opps"]
 ]

Answer 2

ValueQ should do exactly what you want. From the documentation: ValueQ[expr] gives True if a value has been defined for expr, and gives False otherwise. ValueQ gives False only if expr would not change if it were to be entered as Wolfram Language input.

So

ValueQ[Integrate[Log[3 x]^5*Sec[3 x], x]]
(* False *)

and

ValueQ[Integrate[Sec[3 x], x]]
(* True *)