How to create ordered and custom formatted random matrices?

Question

I'm trying to generate square grid templates to drill holes on a plate for a fragmentation experiment. I have three different problems that I'm not finding a way to solve using the documentation, they are:

1. I need to keep track of the order in which the cells would be drilled, but I couldn't find a way to do this using SparseArray.
2. I which to apply a conditional formating rule where the cells that would be drilled have a dark gray background and white number, but thus far all my attempts to use conditions with Grid options failed.
3. I need to be able to generate and print a large number of these templates, I would usually use Table or TableForm to do this, but since I don't know a way to divide the array into a matrix/grid I'm not getting an output that is printer friendly.

The basics of the program is this:

GridTemplate[msize_, ndrill_] := Module[{ms, nd},
(*creates a square grid template of size msize and number of drilling holes ndrill*)
  ms = msize;
  nd = ndrill;
  Grid[SparseArray[# -> 1 & /@ Table[RandomInteger[{1, ms}, 2], {nd}]], Frame -> All]]

Answer 1

gridTemplate[msize_, ndrill_] := Grid[SparseArray[
   MapIndexed[# -> Item[Style[#2[[1]], White], Background -> Gray] &, 
    RandomSample[Tuples[Range[msize], 2], ndrill], 1], {msize, msize}], Frame -> All]

gridTemplate[10, 5]

Alternatively,

gridTemplate2[msize_, ndrill_] := Grid[SparseArray[Thread[
RandomSample[Tuples[Range[msize], 2], ndrill] -> 
 Array[Item[Style[#, White], Background -> Gray] &, ndrill]], {msize, msize}], Frame->All]

gridTemplate2[10, 10]

Answer 2

In the original program I didn't account for the possibility of duplicated sites, so I've modified the code provided in the answer provided by @kglr to delete duplicate site entries and continue until the desired number of occupied site. Hope it helps.

gridTemplate[msize_, ndrill_] := Module[{l},
  (* msize is the size of the grid's square matrix
    ndrill is the number of holes made in the plate *)
  l = {};
  While[Length[l] < ndrill, 
   l = Append[l, RandomInteger[{1, msize}, 2]] // DeleteDuplicates];
  Grid[SparseArray[
    MapThread[# -> Item[Style[#2, White], Background -> Gray] &, {l, 
      Range[ndrill]}], {msize, msize}], Frame -> All]]