1
$\begingroup$
coord[th_] = {Sech[th]*Cos[th + v], Sech[th]*Sin[th + v], Tanh[th]};
loxo45 = ParametricPlot3D[coord[th], {th, 0, Pi}, {v, .0, 2 Pi},   
PlotLabel -> "3_D WirePlt", PlotStyle -> {Thick, Yellow},PlotRange -> All]

Using ListPlot3D or otherwise please help show how to avoid parallel lines and also the surface so that only the spirals are visible? (Like in ParametricPlot3D but with multiple rotated lines)

$\endgroup$
2
$\begingroup$

Try with this (play with Mesh):

loxo45 = ParametricPlot3D[coord[th], {th, 0, Pi}, {v, .0, 2 Pi}, 
PlotLabel -> "3 _D WirePlt", PlotStyle -> None, PlotRange -> All, 
Mesh -> {0, 20}, MeshStyle -> {{}, {Red, Thickness[0.01]}}]

enter image description here

$\endgroup$
3
$\begingroup$

Single-parameter ParametricPlot3D

ParametricPlot3D[Evaluate @ Table[coord[th], {v, 0, 2 Pi, 2 Pi/20}], {th, 0, Pi}, 
 PlotStyle -> Directive[Red, Thick]]

enter image description here

RotationTransform

line = ParametricPlot3D[coord[th] /. v->0, {th, 0, Pi}, PlotStyle->Directive[Thick, Red]];
Graphics3D[Table[GeometricTransformation[line[[1]], RotationTransform[a, {0, 0, 1}]], 
 {a, Range[0, 2 Pi, 2 Pi/20]}], Axes -> True]

enter image description here

If you wish make Lines into Tubes:

% /. Line -> (Tube[#, .02] &)

enter image description here

$\endgroup$
  • $\begingroup$ very nice adds, +1 $\endgroup$ – José Antonio Díaz Navas Feb 6 '18 at 17:22
  • $\begingroup$ Thank you @JoséAntonioDíazNavas. $\endgroup$ – kglr Feb 6 '18 at 17:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.