How to prevent the loss of Tooltip when using ListLinePlot?

Question

Version 9, windows 7:

When I use ListLinePlot Tooltip does not work any more. It seems to have been lost somewhere. With same data, Tooltip works ok using ListPlot.

data = Table[Tooltip[{x, x^2}], {x, 0, 10, .1}];
ListPlot[data]
(* Tooltip shows ok *)

ListLinePlot[data]
(* Tooltip does not show up *)

Looked at possible issues for ListLinePlot and do not seen mention of this.

question: How to make Tooltip work with ListLinePlot

thanks

Answer 1

Well it will get lost even in the case of ListPlot if you go to continuous solid line case:

ListPlot[data, Joined -> True]

In both cases the fix is to bring back points somehow, for example using Mesh:

ListLinePlot[data, Mesh -> All, MeshStyle -> Opacity[0]]

OR any similar trick in that manner:

Show[ListLinePlot[data], ListPlot[data, PlotStyle -> Opacity[0]]]

The reason for this is probably the fact that in bare solid-line case you get only line segments in resulting Graphics primitives (check with InputForm[..."your plot"...]). And line segments are wrong to wrap Point tool-tips around.

@MikeHoneychurch recommendation will work too; if you want to see only the solid line (with no point marks) something like empty string this will do

ListLinePlot[data, PlotMarkers -> ""]

To answer Mike's comment on Tooltip on line segments - it does work if constructed properly, for example (otherwise mma wouldn't know what to show when mouseover happens, I think):

data = Table[{x, x^2}, {x, 0, 10, .1}];
Graphics[Tooltip[Line[#]] & /@ Partition[data, 2, 1]]

Answer 2

As Vitaly has indicated, you need to have a point to tooltip over. Another approach is to add plot markers -- not suitable if a large number of points present:

data = Table[Tooltip[{x, x^2}], {x, 0, 10, .1}];
ListLinePlot[data, PlotMarkers -> Automatic]

Edit

As per my conversation with Vitaly you can tooltip your line. I had forgotten about that.

data = Table[{x, x^2}, {x, 0, 10, .1}];
ListLinePlot[Tooltip[data, "this line is my data"]]