Filling in Show[]

Question

Is it possible to fill the region between two ListPlots' in Show[]. Something like:

plot1 = ListPlot[f1,Joined->True]
plot2 = ListPlot[f2,Joined->True]
both = Show[plot1,plot2,Filling->{1->{2}}]

my lists f1 and f2 are huge and complicated and has to be computed and plotted separately, i.e. a solution of the form ListPlot[f1,f2,{x,xmin,xmax},Filling->...] is not what I'm looking for. Is this possible and how?

Minimal Example:

list1 = Table[-(x - 2)^2 + 1, {x, 0, 3, 0.1}];
list2 = Table[(x - 1)^2, {x, 0, 3, 0.1}];
plot1 = ListPlot[list1, Joined -> True,DataRange -> {0, 3}]
plot2 = ListPlot[list2, Joined -> True,DataRange -> {0, 3}]
both = Show[plot1,plot2]

Here I would like the region between the plots shaded.

As per the comments I should add that:

The lists list1 and list2 two themselves are lists/matrices. They have dimensions such as 6 times 110 each. Then the object temp = {list1, list2} has Dimension[temp] = {2,6,110} which cannot be ListPlotted straight away.

Answer 1

If you must do this after the lists have been plotted, you can simply grab the lists from the plot,

lines = FirstCase[#, Line[x_] :> x, Nothing, Infinity] & /@ {plot1, 
    plot2};
ListLinePlot[lines, Filling -> {1 -> {2}}]

Answer 2

Here's one way to manually tackle the problem. Might be a little rough around the edges and need some clean up to be more robust, but its a start.

Generate polygon filling:

f1 = Table[{x, Sin[x]}, {x, 0, 10, .1}];
f2 = Table[{x, Cos[x]}, {x, 0, 10, .1}];
mins = If[#[[1, 2]] < #[[2, 1]], #[[1]], #[[2]]] & /@ 
   Transpose[{f1, f2}];
maxes = If[#[[1, 2]] < #[[2, 1]], #[[2]], #[[2]]] & /@ 
   Transpose[{f1, f2}];
joined = Join[mins, Reverse@maxes];
gr = Graphics[{LightBlue, Polygon[joined]}]

Combine with ListPlots:

plot1 = ListPlot[f1, Joined -> True];
plot2 = ListPlot[f2, Joined -> True];
both = Show[{plot1, plot2, gr}]