# Parallel surface error in image visualization

I am missing something basically in this attempt to get at a surface parallel to X = $( u+v,u-v, u v )$. Partial derivatives w.r.t. $(u,v)$ are $X_u = (1,1,v), \, X_v = (1,-1,u)$ erected normal length $-p$

Cross product calculation for a parallel surface after normalizing gives $(u+v, v-u,-2)/\sqrt{2(u^2+v^2+2)}$ but image is unconvincing, which please help in finding out.

 g1 = ParametricPlot3D[{u + v, u - v, u v}, {u, -1, 1}, {v, -1, 1},
PlotLabel -> "\[Psi] "]
p = -1;
g2 =
ParametricPlot3D[
p { u + v, v - u, -2}/Sqrt[2 u^2 + 2 v^2 + 4] , {u, -1.5,
1.5}, {v, -1.5, 1.5}, PlotLabel -> "\[Phi]\[Phi]\[Phi] "]
Show[{g1, g2}, PlotRange -> All]


EDIT1:

Interesting parallel surface of a helicoid with edge of regression (a central cusped spine !?) obtained by suggestions here (goldberg/Schumacher) is convincing 3D imagery.

• I must be missing something, but why can't you just translate your first curve in z? – b3m2a1 Jan 30 '18 at 18:27
• The position vector (that I clean forgot ) is a $variable$ part that should be pre-added to Gauss image. A fixed shift misses out the datum patch. – Narasimham Feb 3 '18 at 9:19

You plot the Gauss image, not the parallel surface. This plots a family of parallel surfaces:

f = {u, v} \[Function] {u + v, u - v, u v};
ν = {x, y} \[Function] Evaluate[Normalize[Cross[D[f[x, y], x], D[f[x, y], y]]]];

Manipulate[
ParametricPlot3D[{f[u, v], f[u, v] + t ν[u, v]}, {u, -1.5, 1.5}, {v, -1.5, 1.5},
AxesLabel -> {x, y, z},
BoxRatios -> {1, 1, 1},
ViewPoint -> {2000, -1500, 650},
ViewAngle -> .033 Degree,
SphericalRegion -> True,
PlotRange -> {{-5, 5}, {-5, 5}, {-4, 4}}],
{{t, 0}, -2, 2, .1, AppearanceElements -> All}]


• I made some edits that I think improve your answer. If you disagree, then don't hesitate to roll back my changes. – m_goldberg Jan 29 '18 at 2:22
• @m_goldberg Nah, it's fine. Good idea to show the reference surface! =) – Henrik Schumacher Jan 29 '18 at 7:05
• Thanks to you both @HenrikSchumacher and & m_goldberg: I could see in another $f$ example an edge of regression for a helicoid. – Narasimham Jan 29 '18 at 19:41
• @m_goldberg Just a ping to bring your attention to the comment above by Narasimham. – Henrik Schumacher Jan 29 '18 at 21:28