Joining all the keys of a list of rules that point to matching values

Question

Suppose I have a list of rules whose keys are not of identical structure (in my case, the keys are either lists of at least one symbol or symbols alone):

rules = {{a} -> 1, {b, c} -> 1, d -> 2, {e, f} -> 2, {g, g} -> 3, g -> 4};

The aim is to get all keys with matching values grouped together to end up with

newRules = {{a, b, c} -> 1, {d, e, f} -> 2, {g, g} -> 3, {g} -> 4};

I have what seems to me to be a hacky attempt to do this:

Reverse /@
    Normal[
        Merge[
            Association /@ Reverse /@ rules, Flatten]
        ] == newRules
(* True *)

Are there any better ways to do this?

Answer 1

There are many ways, here's one:

KeyValueMap[#2 -> # &] @ GroupBy[rules, Last -> First, Flatten]

Answer 2

Reverse /@ (Flatten /@ PositionIndex[Association@rules] // Normal) 

{{a, b, c} -> 1, {d, e, f} -> 2, {g, g} -> 3, {g} -> 4}

In addition:

Flatten /@ PositionIndex[Association@rules]

<|1 -> {a, b, c}, 2 -> {d, e, f}, 3 -> {g, g}, 4 -> {g}|>

Answer 3

Reap[Sow @@@ (List @@@ rules), _, Flatten[{#2}] -> #1 &][[-1]]

yields:

{{a, b, c} -> 1, {d, e, f} -> 2, {g, g} -> 3, {g} -> 4}

Answer 4

KeyValueMap[#2 -> #&] @ Merge[Flatten][Reverse /@ rules]

{{a, b, c} -> 1, {d, e, f} -> 2, {g, g} -> 3, {g} -> 4}

Als0

Flatten[#[[All, 1]]] -> #[[1, -1]]& /@ GatherBy[rules, Last] 

{{a, b, c} -> 1, {d, e, f} -> 2, {g, g} -> 3, {g} -> 4}

and

Values @ GroupBy[rules, Last, Flatten @ #[[All, 1]] -> #[[1, -1]]&] 

{{a, b, c} -> 1, {d, e, f} -> 2, {g, g} -> 3, {g} -> 4}