9
$\begingroup$

Is there a trick to make Mathematica solve

$${\frac {\partial^{2} u}{\partial {x}^{2}}} +{\frac {\partial ^{2} u}{\partial {y}^{2}}} =0$$ with one boundary condition at $\infty$?

Boundary conditions are

$$ \begin{align*} u \left( 0,y \right) &=\sin \left( y \right) \\ u \left( x,0 \right) &=0 \\ u \left( x,a \right) &=0\\ u \left( \infty ,y \right) &=0 \end{align*} $$

Maple can solve this analytically, but one must tell it to assume $a>0$. But I can't get Mathematica 11.2 to solve it. Even when $a$ is given a numerical value. This is last problem listed here

Mathematica can solve it only by removing the $\infty$ boundary condition and making it finite.

Here is the code

ClearAll[x,y,a]
ode=D[u[x,y],{x,2}]+D[u[x,y],{y,2}]==0;
bc={u[x,0]==0,u[x,a]==0,u[0,y]==Sin[y],u[Infinity,y]==0};
Assuming[a>0,DSolve[{ode,bc},u[x,y],{x,y}]]

I think Assuming[a>0 above is not even used by DSolve. Also with a being numerical, it does not solve it:

ClearAll[x,y,a]
a=2;
ode=D[u[x,y],{x,2}]+D[u[x,y],{y,2}]==0;
bc={u[x,0]==0,u[x,a]==0,u[0,y]==Sin[y],u[Infinity,y]==0};
DSolve[{ode,bc},u[x,y],{x,y}]

Maple 2017 solves it, and gives this

ode:=diff(u(x,y),x$2)+diff(u(x,y),y$2)=0;
bc:=u(x,0)=0, u(x,a)=0, u(0,y)=sin(y), u(infinity,y)=0;
sol:=pdsolve({ode, bc}, u(x,y)) assuming a>0; 

$$ u \left( x,y \right) =\sum _{n=1}^{\infty }2\,{\frac { \left( -1 \right) ^{1+n}\pi\,\sin \left( a \right) n}{{\pi}^{2}{n}^{2}-{a}^{2}} \sin \left( {\frac {\pi\,yn}{a}} \right) {{\rm e}^{-{\frac {\pi\,xn}{a }}}}} $$

Screen shot

Mathematica graphics

Any one knows of a trick to make Mathematica solve this symbolically?

$\endgroup$
  • $\begingroup$ Perhaps, Mathematica is having difficulties, because the initial and boundary conditions are inconsistent. It is, of course, possible to Fourier-decompose the PDE in y, but the resulting solution does not converge uniformly. $\endgroup$ – bbgodfrey Dec 28 '17 at 5:14
  • $\begingroup$ @bbgodfrey oh, that was just me changing the PDE while playing around with it. The original one had Sin[y] there. But M still can't solve it. I should correct this now. Thanks. $\endgroup$ – Nasser Dec 28 '17 at 5:25
15
$\begingroup$

Using the symbolic boundary condition

u[t, y] == 0

instead of the infinite one, and then taking the limit $$ t \to \infty,$$ inside the sum seems to do the trick for me.

ClearAll[x, y, a]
ode = D[u[x, y], {x, 2}] + D[u[x, y], {y, 2}] == 0;
bc = {u[x, 0] == 0, u[x, a] == 0, u[0, y] == Sin[y], u[t, y] == 0};
sol = Assuming[a > 0, DSolve[{ode, bc}, u[x, y], {x, y}]];
expr = (u[x, y] /. sol)[[1]][[1]];
limexpr = 
  Assuming[ a > 0 && K[1] > 0, Limit[expr, t -> \[Infinity]]];
Inactivate[Sum[limexpr, {K[1], 1, \[Infinity]}]]

This gives $$\underset{K[1]=1}{\overset{\infty }{\sum }}-\frac{2 \pi \sin (a) (-1)^{K[1]} K[1] e^{-\frac{\pi x K[1]}{a}} \sin \left(\frac{\pi y K[1]}{a}\right)}{\pi ^2 K[1]^2-a^2}$$

| improve this answer | |
$\endgroup$
  • $\begingroup$ Thanks. btw, the original PDE had sin not cos. This does not affect your method. Just wanted to point I made change to the PDE now. $\endgroup$ – Nasser Dec 28 '17 at 5:29
  • $\begingroup$ I've updated the solution to reflect this :) $\endgroup$ – ZufolgeWeierstrass Dec 30 '17 at 3:27

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.