0
$\begingroup$

I want to find positive solution to an equation $\text{Solve}\left[t==\frac{\sqrt{\left(\frac{L}{\gamma }+t v\right)^2+x^2}}{c}\land \text{assume},t\right]$.

Although using many assumptions, Mathematica provides a negative solution as explained in what follows.

A similar but simpler equation works as expected.

How can I obtain the positive solution to the equation

First a little context:

I'm using Solve to solve for t:

t11s1 = Solve[t == Sqrt[(L + v*t)^2 + (x)^2]/(c), t]

The solution are two roots:

$$ \left\{\left\{t\to \frac{L v-\sqrt{c^2 L^2+c^2 x^2-v^2 x^2}}{c^2-v^2}\right\},\left\{t\to \frac{\sqrt{c^2 L^2+c^2 x^2-v^2 x^2}+L v}{c^2-v^2}\right\}\right\} $$

This I Refine with some assumptions, and get a positive solution:

$$ \left\{\frac{\sqrt{c^2 L^2+c^2 x^2-v^2 x^2}}{c^2-v^2}+\frac{L v}{c^2-v^2}\right\} $$

However, if instead of $L$ I use $L\rightarrow\frac{L}{\sqrt{1-\frac{v^2}{c^2}}}$ which is a positive, real multiplicative factor on $L$, the solution changes to

$$ \left\{\left\{t\to \text{ConditionalExpression}\left[\text{Root}\left[\text{$\#$1}^4 \left(c^8-2 c^6 v^2+c^4 v^4\right)+\text{$\#$1}^2 \left(-2 c^6 L^2-2 c^6 x^2+2 c^4 v^2 x^2+2 c^2 L^2 v^4\right)+c^4 L^4+2 c^4 L^2 x^2+c^4 x^4-2 c^2 L^4 v^2-2 c^2 L^2 v^2 x^2+L^4 v^4\&,4\right],v>0\land c>v\land x>0\land L>x\land 0<a<x\land 0<n<\frac{c}{v}\right]\right\}\right\} $$

which if I force to be expressed as radicals (to eliminate the Root[,4]) and again I refine using the same assumptions I get

$$ \left\{-\sqrt{\frac{c^2 \left(L^2+x^2\right)+2 c L v \sqrt{L^2+x^2}+L^2 v^2}{c^4-c^2 v^2}}\right\} $$

which is a negative value because all variables are Reals !!

My assumptions are:

$$ \text{assume}=v>0\land v\in \mathbb{R}\land L>0\land L\in \mathbb{R}\land \text{L2}>0\land \text{L2}\in \mathbb{R}\land a>0\land a\in \mathbb{R}\land t>0\land t\in \mathbb{R}\land c>0\land c\in \mathbb{R}\land n>0\land n\in \mathbb{R}\land \gamma >0\land \gamma \in \mathbb{R}\land \beta \geq 0\land \beta <1\land \beta \in \mathbb{R}\land c>v\land x\in \mathbb{R}\land x>0\land n<\frac{c}{v}\land L>x\land L>a\land x>a $$

and I use them as:

$$ \text{t11s2}=\text{Solve}\left[t==\frac{\sqrt{\left(\frac{L}{\gamma }+t v\right)^2+x^2}}{c}\land \text{assume},t\right] $$

$$ \text{t2}=\text{Simplify}[\text{ToRadicals}[\text{Refine}[t\text{/.}\, \text{t11s2},\text{assume}]],\text{assume}] $$

to get

$$ t2=\left\{-\sqrt{\frac{c^2 \left(L^2+x^2\right)+2 c L v \sqrt{L^2+x^2}+L^2 v^2}{c^4-c^2 v^2}}\right\} $$

What can I do to recover a positive real values for t? Why is Mathematica behaving like this?

$\endgroup$
  • $\begingroup$ Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour and check the faqs! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! $\endgroup$ – Henrik Schumacher Dec 27 '17 at 22:30
  • 1
    $\begingroup$ Please post your actual Mathematica code, not a MathJax version of it. Nobody wants to type in code from MathJax when you could simply post it in a form that allows copy and paste. Without code no one will be able to work with it to see what could be done better, nor will they be able to experiment with possible improvements. $\endgroup$ – m_goldberg Dec 27 '17 at 22:34
  • $\begingroup$ I don't think it is possible for ToRadicals to give a parametrized result that will consistently respect assumptions on the parameters. Root objects and radicals have a way of crossing. Which is to say, a given radicals might equal a given root object for one set of parameter values, and another root object for a different set of values. This is indicated in the Possible Issues section of the reference page for ToRadicals. $\endgroup$ – Daniel Lichtblau Dec 28 '17 at 0:33
2
$\begingroup$

I think it would be simpler to use Solve without assumptions, and then simplify after:

res = t /. Solve[t == Sqrt[(L/Sqrt[1-v^2/c^2]+v*t)^2 + x^2]/c, t];
Simplify[res, 0 < v < c] //TeXForm

$\left\{\frac{c L v-\sqrt{c^4 \left(L^2+x^2\right)-2 c^2 v^2 x^2+v^4 x^2}}{\left(c^2-v^2\right)^{3/2}},\frac{\sqrt{c^4 \left(L^2+x^2\right)-2 c^2 v^2 x^2+v^4 x^2}+c L v}{\left(c^2-v^2\right)^{3/2}}\right\}$

On the other hand, to fix your approach, you can use the undocumented option Assumptions for ToRadicals:

assum = 0<v<c && L>0 && t>0 && x>0;

res = t /. First @ Solve[
    t==Sqrt[(L/Sqrt[1-v^2/c^2]+v*t)^2 + x^2]/c && assum,
    t
];

FullSimplify[
    ToRadicals[res, Assumptions->assum],
    assum
] //TeXForm

$\sqrt{\frac{c^4 L^2+c^2 L^2 v^2+x^2 \left(c^2-v^2\right)^2+2 c L v \sqrt{c^4 L^2+x^2 \left(c^2-v^2\right)^2}}{\left(c^2-v^2\right)^3}}$

$\endgroup$
  • $\begingroup$ You made it so simple! Thanks! $\endgroup$ – arod Dec 27 '17 at 23:01
  • $\begingroup$ perhaps you can help me with this follow up question $\endgroup$ – arod Dec 28 '17 at 1:17

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.