6
$\begingroup$

I want to get the area of the set $\{x^2 + y\, | \,x^2 + y^2 < 2\}$, meaning I want to get the area of the surface defined by

$\qquad f(x,y) = x^2 + y$

with the domain given by $x^2 + y^2 < 2$.

I tried using ImplicitRegion, and I can even plot it with 

Plot3D[x^2 + y, {x, y} ∈ ImplicitRegion[x^2 + y^2 < 2, {x, y}]]

but I don't know how to measure the area of the surface.

Improve this question
$\endgroup$
2
  • 1
    $\begingroup$ It is unclear what you're asking. What does it mean the "area" of $x^2 + y$? And why is your domain $x^2 + y^2 < 2$ but your Plot3D have an ImplicitRegion $x^2 + y^2 < 9$? Please fix your question! $\endgroup$ – David G. Stork Dec 14 '17 at 21:51
  • 1
    $\begingroup$ The Plot3D also plots a different function (2x+y) instead of (x^2+y). $\endgroup$ – Cassini Dec 14 '17 at 21:58
12
$\begingroup$

I believe the question is about the area of a surface. If that's the case, the answer is as follows:

surface = ImplicitRegion[x^2 + y == z && x^2 + y^2 < 2, {x, y, z}]

This is a 2D region embedded in 3D space:

RegionDimension[surface]
RegionEmbeddingDimension[surface]
(*2*)
(*3*)

The area is found by using RegionMeasure:

RegionMeasure[surface]
N[%, 10]
(*2/3 Sqrt[2] (3 EllipticE[-4] + 5 EllipticK[-4])*)
(*12.21203137*)
Improve this answer
$\endgroup$
1
  • $\begingroup$ This is exactly what I wanted, thanks a lot! $\endgroup$ – Csharphobbydev Dec 15 '17 at 15:21
4
$\begingroup$ 
Integrate[x*x + y, {x, y} ∈ Disk[{0, 0}, Sqrt [2]]]

which returns $\pi$.

However, if it is school work, the "manual" way to do that is a change of variable like this one: $(x,y)=(r\cos \theta,r\sin \theta)$

After Jacobian calculation you get: 

Integrate[r*(r*r*Cos[θ]^2 + r*Sin[θ]), {r, 0, Sqrt[2]}, {θ, 0, 2 π}]

Which (fortunately) also gives $\pi$

Update: Now if you want area of the surface, you can use this formula: $$ \int_\Omega \| \left( \begin{array}{c} 1 \\ 0 \\ \partial_x f \end{array} \right)\times \left( \begin{array}{c} 0 \\ 1 \\ \partial_y f \end{array} \right) \| dxdy $$ with $\Omega$ your centered disk of radius $\sqrt{2}$ and $f:(x,y)\rightarrow x^2+y$. You get, after change of variable $$ \int_0^\sqrt{2}\int_0^{2\pi} r \sqrt{4 r^2 \cos ^2(\theta )+2}\ drd\theta $$ which unfortunately involves Elliptic functions...

Under Mathematica:

f[x_, y_] := x*x + y

vx = D[{x, y, f[x, y]}, x];
vy = D[{x, y, f[x, y]}, y];

dareaCartesian = 
 Simplify[Norm[Cross[vx, vy], 2], Assumptions -> {x ∈ Reals}]

dareaPolar = 
 r*Simplify[dareaCartesian /. x -> r*Cos[θ] /. y -> r*Sin[θ] ]

area = Integrate[dareaPolar, {r, 0, Sqrt[2]}, {θ, 0, 2*Pi}] 

N[area]

which prints: $$ \sqrt{4 x^2+2} $$ $$ r \sqrt{4 r^2 \cos ^2(\theta )+2} $$ $$ \frac{2}{3} \sqrt{2} (5 EllipticK(-4)+3 EllipticE(-4)) $$ $$ 12.212 $$

Improve this answer
$\endgroup$
2
$\begingroup$ 
    Integrate[(x^2 + y) Boole[x^2 + y^2 < 2], {x, -Infinity, 
   Infinity}, {y, -Infinity, Infinity}]

Pi

(* If you want a plot, do this: *)

 Plot3D[(x^2 + y) Boole[x^2 + y^2 < 2], {x, -Sqrt[2], 
  Sqrt[2]}, {y, -Sqrt[2], Sqrt[2]}, 
 RegionFunction -> (#1^2 + #2^2 < 2 &), Filling -> Axis, 
 FillingStyle -> Directive[Gray, Opacity[0.2]]]
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.