# Transform integral to elliptic or hypergeometric forms?

I have two integrals that I suspect can be expressed as elliptic integrals:

$$\int_0^{2\pi} d\phi' \frac{1}{( 1 + \alpha^2 + \beta^2 - 2 \beta \cos(\phi') )^{3/2}}$$ $$\int_0^{2\pi} d\phi' \frac{\cos(\phi')}{( 1 + \alpha^2 + \beta^2 - 2 \beta \cos(\phi') )^{3/2}}$$

Is there a way to have Mathematica attempt to transform these into elliptic integrals?

When doing the indefinite integrals and taking the limits, you get the results very fast.

int1[p_, a_, b_] = Integrate[1/(1 + a^2 + b^2 - 2 b Cos[p])^(3/2), p,
Assumptions ->
a \[Element] Reals && b \[Element] Reals && 0 <= p <= 2 Pi]

lim1t = Limit[int1[p, a, b], p -> 2 Pi, Direction -> 1,
Assumptions -> a \[Element] Reals && b \[Element] Reals]

(*    (4 EllipticE[-((4 b)/(a^2 + (-1 + b)^2))])/(Sqrt[
a^2 + (-1 + b)^2] (a^2 + (1 + b)^2))    *)

lim1b = Limit[int1[p, a, b], p -> 0, Direction -> -1,
Assumptions -> a \[Element] Reals && b \[Element] Reals]

(*    0    *)

int2[p_, a_, b_] = Integrate[Cos[p]/(1 + a^2 + b^2 - 2 b Cos[p])^(3/2), p,
Assumptions -> a \[Element] Reals && b \[Element] Reals]

lim2t = Limit[int2[p, a, b], p -> 2 Pi, Direction -> 1,
Assumptions -> a \[Element] Reals && b \[Element] Reals]

(*    (2 (1 + a^2 + b^2) EllipticE[-((4 b)/(a^2 + (-1 + b)^2))] -
2 (a^2 + (1 + b)^2) EllipticK[-((4 b)/(a^2 + (-1 + b)^2))])/(Sqrt[
a^2 + (-1 + b)^2] b (a^2 + (1 + b)^2))    *)

lim2b = Limit[int2[p, a, b], p -> 0, Direction -> -1,
Assumptions -> a \[Element] Reals && b \[Element] Reals]

(*    0    *)


So the definite integrals are lim1t and lim2t.

In version 12.0

Integrate[1/(1 + \[Alpha]^2 + \[Beta]^2 - 2 \[Beta] Cos[\[Phi]])^(3/
2), {\[Phi], 0, 2*Pi}, GenerateConditions -> False]


$$\frac{4 E\left(-\frac{4 \beta }{\alpha ^2+(\beta -1)^2}\right)}{\sqrt{\alpha ^2+(\beta -1)^2} \left(\alpha ^2+(\beta +1)^2\right)}$$

Integrate[Cos[\[Phi]]/(1 + \[Alpha]^2 + \[Beta]^2 - 2 \[Beta] Cos[\[Phi]])^(3/
2), {\[Phi], 0, 2*Pi}, GenerateConditions -> False]


$$\frac{2 \left(\alpha ^2+\beta ^2+1\right) E\left(-\frac{4 \beta }{\alpha ^2+(\beta -1)^2}\right)-2 \left(\alpha ^2+(\beta +1)^2\right) K\left(-\frac{4 \beta }{\alpha ^2+(\beta -1)^2}\right)}{\beta \sqrt{\alpha ^2+(\beta -1)^2} \left(\alpha ^2+(\beta +1)^2\right)}$$

I was able to do this after a manual transformation (related to the original integrals by a factor of $2 (\alpha^2 + (1-\beta)^2)^{3/2}$) :

\$Assumptions =
beta >= 0 && alpha \[Element] Reals && (1 - beta)^2 + alpha^2 != 0;

i1 = Integrate[ (
1 + 4 beta Sin[u]^2/((1 - beta)^2 + alpha^2))^(-3/2), {u, 0, Pi}]

i2 = Integrate[
Cos[2 u] ( 1 + 4 beta Sin[u]^2/((1 - beta)^2 + alpha^2))^(-3/2), {u,
0, Pi}]


and then waiting a very long time (around an hour). The results comes back as not very illuminating sums of EllipticE and EllipticK functions.

Perhaps Mathematica would have given me a similar result for Integrate[]'s of the original integrands? However, I was too impatient, and Aborted the evaluation, thinking that it was hung.