Possible bug in integral with PolyLog and Zeta

Question

$Version

"10.1.0 for Microsoft Windows (64-bit) (March 24, 2015)"

The following integral was nicely and quickly done by Mathematica

i1 = Integrate[1/(1 - x) (PolyLog[3, -x] + 3/4 Zeta[3]), {x, 0, 1}]

(* Out[1027]= (3 Zeta[3])/4 *)

% // N

(* Out[1028]= 0.901543 *)

But unfortunately the result is wrong.

This can be seen looking at the numerical integral

i2 = NIntegrate[1/(1 - x) (PolyLog[3, -x] + 3/4 Zeta[3]), {x, 0, 1}]

(* Out[1029]= 0.859247 *)

The results differ appreciably.

Also it can be shown [1] that the integral is equivalent the following infinite sum

$$s= \sum _{k=1}^{\infty } \frac{(-1)^{k+1} H_k}{k^3}$$

Numerically this is

i3 = NSum[(-1)^(k + 1)/k^3 HarmonicNumber[k], {k, 1, 10^4}, 
  WorkingPrecision -> 10, Method -> "AlternatingSigns"]

(* Out[1036]= 0.8592466552 *)

This result is in agreement with $i2$. Hence we conclude that Mathematica returns a wrong result for the integral $i1$.

References

[1] https://math.stackexchange.com/questions/275643/proving-an-alternating-euler-sum-sum-k-1-infty-frac-1k1-h-kk/276590#276590

Answer 1

Problem was corrected by at least v11.2

$Version

(* "11.2.0 for Mac OS X x86 (64-bit) (September 11, 2017)" *)

i1 = Integrate[1/(1 - x) (PolyLog[3, -x] + 3/4 Zeta[3]), {x, 0, 1}]

(* (3/4)*EulerGamma*Zeta[3] - 
   Derivative[{0, 0, 0, 0}, 
         {0, 0, 1}, 0][
       HypergeometricPFQRegularized][
     {1, 1, 1, 1}, {2, 2, 2}, -1] *)

i1 // N

(* 0.859247 *)

% == NIntegrate[1/(1 - x) (PolyLog[3, -x] + 3/4 Zeta[3]), {x, 0, 1}]

(* True *)

Answer 2

It is possible to solve the problem also in V10.1.0.

We calculate the integral with a variable $x$ instead of $1$ and let $x\to 1$ afterwards.

In fact

Integrate[
 1/(1 - z) (PolyLog[3, -x] - PolyLog[3, -x z]), {z, 0, 1}, 
 Assumptions -> x > 0]

(* PolyLog[3,-x]+x \
(HypergeometricPFQ^({0,0,0,0},{0,0,1},0))[{1,1,1,1},{2,2,2},-x] *)

Now let $x\to 1$

(* PolyLog[3,-x]+x \
(HypergeometricPFQ^({0,0,0,0},{0,0,1},0))[{1,1,1,1},{2,2,2},-x]/.x\
\[Rule]1 *)

(* -0.8592471579285906` *)

The exact value can be shown to be

-((11 \[Pi]^4)/360) - 1/12 \[Pi]^2 Log[2]^2 + Log[2]^4/12 + 
  2 PolyLog[4, 1/2] + 7/4 Log[2] Zeta[3] // N

(* Out[6]= -0.859247 *)