0
$\begingroup$

I am analyzing a discrete dynamic quadratic map. The bifurcation diagram shows the existence of an asymptotic 3- cycle periodic point for a given parameter. But the graphic of the lyapunov exponent gives a positive coefficient.
My map quad[{x,y}] is {x + K x (2. - 0.76 x - 0.4 y), y + K (2. - 0.6 x - 0.5 y) y}. I am working on 3-periodic cycle. The bifurcation diagram shoes that there an asymptotic convergent 3-cycle period at the value of the parameter K=K = 1.417. When I take the map quad3 and analyze fixed point by writing quad3[{x_, y_}] = Simplify[quad[quad[quad[{x, y}]]]]; and then : FindRoot[quad3[{x, y}] == {x, y}, {{x, 1.85}, {y, 2.96}}]. I obtain {x -> 1.85234, y -> 2.96374} hence x=1.8523360794543522 and y=2.9637377271382412. When writing x = 1.8523360794543522; y = 2.9637377271382412; and quad3[{x, y}] I obtain x=1.8523360794681456 and y=2.9637377271328504. there is small difference. How to be sure that the fixed point of quad3 exits or equivalently a 3-period cycle exists ?

$\endgroup$
  • $\begingroup$ What have you tried? What is your code? And can you try to give a specific question, too. $\endgroup$ – aardvark2012 Nov 26 '17 at 10:22
  • $\begingroup$ My map f[{x,y}] is {x + K x (2. - 0.76 x - 0.4 y), y + K (2. - 0.6 x - 0.5 y) y}. I am working on 3-periodic cycle. The bifurcation diagram shoes that there an asymptotic convergent 3-cycle period at the value of the parameter K=K = 1.417. When I take the map f3 and analyze fixed point by $\endgroup$ – khaled Nov 26 '17 at 12:24
  • $\begingroup$ You could try increasing the WorkingPrecision of FindRoot. See also AccuracyGoal and PrecisionGoal. $\endgroup$ – aardvark2012 Nov 26 '17 at 12:50
  • $\begingroup$ How'd you get the bifurcation diagram and Lyapunov exponents? $\endgroup$ – Chris K Nov 26 '17 at 15:25
2
$\begingroup$

I don't think the 3-cycle you found at K=1.417 is stable. Here are two lines of evidence:

First, simulate the map (warmup for 100 steps, then plot the next 20) and see:

quad[{x_, y_}] := {x + K x (2. - 0.76 x - 0.4 y), y + K (2. - 0.6 x - 0.5 y) y};
K=1.417;
ListLinePlot[Transpose[NestList[quad, Nest[quad, {1.85, 3}, 100], 20]]]

Mathematica graphics

Doesn't seem to be settling down to a cycle.

Second, find the eigenvalues of the Jacobian matrix of the 3-step map quad3:

quad3[{x_, y_}] = Simplify[quad[quad[quad[{x, y}]]]];
j3 := D[quad3[{x, y}], {{x, y}, 1}]
eq3 = FindRoot[quad3[{x, y}] == {x, y}, {{x, 1.85}, {y, 2.96}}]
(* {x -> 1.85234, y -> 2.96374} *)
Eigenvalues[j3 /. eq3]
(* {-1.42176, -0.280642} *)

The eigenvalue of -1.42176 indicates instability of the 3-cycle eq3.

One last idea: simulate starting near the unstable 3-cycle to watch the divergence.

ListLinePlot[Transpose[NestList[quad, {x + 10^-4, y} /. eq3, 100]]]

Mathematica graphics

| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.