Change the default font in all plots and legends, even when exporting to PDF

Question

This is a followup to:

• How can I change the default font used in ALL plots and legends in Mathematica?

Carl Woll gave a great answer there: change the "Graphics" style of the current notebook's stylesheet. This is simple to do and indeed affects the style in all GraphicsBoxes.

Unfortunately, the style change does not stick when we export a legended figure to PDF.

Question: How can we work around this problem and preserve the new style even when exporting to PDF?

---

Demonstration:

We set the "Graphics" style for all style environments:

SetOptions[EvaluationNotebook[],
 StyleDefinitions -> Notebook[{
    Cell[StyleData[StyleDefinitions -> "Default.nb"]], 
    Cell[StyleData["Graphics", All], FontFamily -> "Times"]
    },
   StyleDefinitions -> "PrivateStylesheetFormatting.nb"]
 ]

Additionally, we change the printing style environment to "Working". Otherwise Export would use the "Printout" environment for labelled plots, which would downscale everything.

SetOptions[$FrontEndSession, PrintingStyleEnvironment -> "Working"]

Let's try exporting these two plots:

plot1 = DensityPlot[x, {x, -1, 1}, {y, -1, 1}, PlotLabel -> "Plot 1"]
plot2 = DensityPlot[x, {x, -1, 1}, {y, -1, 1}, PlotLabel -> "Plot 2", PlotLegends -> Automatic]

Both use the Times font when displayed in the notebook, but plot2 will revert to the default font when exported to PDF:

---

Note: To be more precise, the problem appears when we export something that is not represented as a GraphicsBox. This is the case with Legended expressions when the legend is placed outside of the plot frame. Row[{plot1}] also doesn't export correctly.

Answer 1

I've reported this issue to the import/export team. One possible workaround is to use export on a notebook object representation of the graphics object. For example:

pdfExport[file_, expr_] := Module[{nb},
    Internal`WithLocalSettings[
        nb = CreateDocument[expr, Visible->False, Options[EvaluationNotebook[], StyleDefinitions]],
        Export[file, nb],
        NotebookClose[nb]
    ]
]

Your examples:

pdfExport["plot1.pdf", plot1];
pdfExport["plot2.pdf", plot2];
pdfExport["rowplot.pdf", Row[{plot1}]];

look correct to me. Another workaround is to modify an internal symbol, I can provide this if the above approach proves unsuitable.

(Internal symbol redefinition)

For completeness, here is the workaround where I modify an internal symbol:

DownValues[System`ConvertersDump`createVectorExportPacketExpr] = ReplaceAll[
    DownValues[System`ConvertersDump`createVectorExportPacketExpr],
    Notebook[a__] :> Notebook[a, Options[EvaluationNotebook[], StyleDefinitions]]
];

It is also possible to modify the first DownValue of System`ConvertersDump`createVectorExportPacketExpr, but I think this version is better.