# FullSimplify seems to be insufficient

I have this rather complicated expression, namely the following.

h[p_, k_] := -(((-1 + k) p Log[(-1 + k) p])/Log[2]) + ((-(1/k) + 1/2
(-1 + k) p) Log[1/k - 1/2 (-1 + k) p])/Log[2] + ((-1 + k) (-2 + k p)
Log[-(((-1 + k) (-2 + k p))/(2 k))])/(2 k Log[2])


And I am then interested in

sol[k_] := 2^h[4/(k (k + Sqrt[-12 + k (12 + k)])), k]


for different $k \in \mathbb{Z}_{\geq 2}$. For $k=2$ the expression is rather simple and it correctly yields $3$. If I look at $k=3$ via

FullSimplify[sol[3]]


it yields the following expression: $$2^{\frac{1}{9} \left(21-4 \sqrt{33}\right)} 3^{\frac{1}{9} \left(21-\sqrt{33}\right)} \left(9-\sqrt{33}\right)^{\frac{1}{18} \left(\sqrt{33}-9\right)} \left(15-\sqrt{33}\right)^{\frac{1}{18} \left(\sqrt{33}-15\right)} \left(3+\sqrt{33}\right)^{\frac{1}{9} \left(\sqrt{33}-3\right)}.$$

I suspect, backed up by numerical evidence, that this expression is equal to $$\frac{3}{8}\left(207+33\sqrt{33}\right)^\frac{1}{3}.$$ Is there a way to make Mathematica simplify the expression further? One of the things that is disappointing about this lack of simplification is that the big expression is not recognized as an algebraic number, while

RootReduce[(3/8) (207 + 33*Sqrt[33])^(1/3)]


does work.

The following combination of operations works quite good

First transform the h to f

f[p_, k_] = h[p, k] // FullSimplify[#, k >= 2 && 0 < p < 1] & // ExpandAll

(*    -((2 Log[1 - 1/k + p/2 - (k p)/2])/Log[4]) + (
2 Log[1 - 1/k + p/2 - (k p)/2])/(k Log[4]) - (
p Log[1 - 1/k + p/2 - (k p)/2])/Log[4] + (
k p Log[1 - 1/k + p/2 - (k p)/2])/Log[4] - (
2 Log[1/k + p/2 - (k p)/2])/(k Log[4]) - (
p Log[1/k + p/2 - (k p)/2])/Log[4] + (k p Log[1/k + p/2 - (k p)/2])/
Log[4] + (2 p Log[-p + k p])/Log[4] - (2 k p Log[-p + k p])/Log[4]    *)

pp = 4/(k (k + Sqrt[-12 + k (12 + k)])) // Apart;

sol[k_] = 2^f[pp, k] // ExpandAll;

sol[3] // FullSimplify // ExpandAll // PowerExpand // Simplify

(*    3/8 (207 + 33 Sqrt[33])^(1/3)    *)

sol[4] // FullSimplify // ExpandAll // PowerExpand // Simplify

(*    Sqrt[70/27 + (26 Sqrt[13])/27]    *)


This gives simple formes up to sol[8], and than more complicated forms

sol[9] // FullSimplify // ExpandAll // PowerExpand // Simplify

(*    3 2^(1/6 (-62 + Sqrt[177])) 3^(2/3) (-9 + Sqrt[177])^(
1/3 - Sqrt[59/3]/9) (43/3 + Sqrt[177])^(-(Sqrt[(59/3)]/
18)) (15 + Sqrt[177])^(5/18) (57 + Sqrt[177])^(19/18)    *)


and so on.

• Thank you! This works well for the small cases. For me $k=6$ already gives a complicated form with a root in the exponent, but then $k=7$ and $k=8$ work well again. – Pjotr5 Nov 19 '17 at 10:18
• Working with Mathematica Version 8.0, sol[6] // FullSimplify // ExpandAll // PowerExpand // Simplify gives (3 (477 + 228 Sqrt[6])^(1/3))/(5 5^(2/3)) – Akku14 Nov 19 '17 at 16:46