Defining a piecewise function with underlying lattice

Question

I'm fairly new to Mathematica, and programming in general, but I'm trying to define an $n$-dimensional piecewise function, $F({\bf x})$. Properties of the function are set by an underlying lattice, defined by a set of primitive vectors, ${\bf a}_i$, where each lattice position is defined by $${\bf R}_A = A_1{\bf a}_1+\dotsc +A_n{\bf a}_n,$$ where $A_i\in\mathbb{Z}.$

Now essentially, I want my function to be some value $V_0$ when it is within a radius $r$ of each lattice position, and $0$ elsewhere. In short, $$F({\bf x})= \begin{cases} V_0 & |{\bf x}-{\bf R}_A| < r \\ 0 & \textrm{Elsewhere} \end{cases}.$$

To simplify the discussion, I'll talk about the $n=1$ case, which is a pulse train, but I'd like to be able to generalize this to higher dimensions.

I've mainly tried to define this function by some variation of

F[x_] := Piecewise[{{V0, Abs[x - a * A] < r}}]

but I've yet to succeed. In my code, I assign some value to a and r, which are my lattice spacing (essentially, my 1D primitive vector) and radius, respectively.

The tricky part comes with dealing with A, as it's not being assigned a particular value, but is instead any element of a set. I've tried declaring Element[A, Integers] before defining F[x] above. I've also tried to use Refine as in

F[x_] := Refine[Piecewise[{{V0, Abs[x - a*A] < r}}], Element[A, Integers]]

but have met with similar results. Every time I try to plot F[x], I just end up with a blank plot. I imagine I'm not setting up my condition correctly, but I don't know how else to let Mathematica know A is any integer. It really seems like there would be an straightforward way to define this function, short of using a Fourier series, but I haven't found out how. Any help would be appreciated, and thank you in advance!

Answer 1

The implementation I gave in the comments had a missing piece. The following should now work:

lattice[x_, v0_, a_, r_] := With[{tr = Transpose[a], per = (# - Round[#]) &}, 
        Piecewise[{{v0, Norm[tr.per[LinearSolve[tr, x]]] < r}}, 0]]

Some examples:

Plot[lattice[{x}, 1, {{1}}, 1/4], {x, -2, 2}, Axes -> None, Frame -> True]

DensityPlot[lattice[{x, y}, 1/4, {{1, 0}, {1/2, Sqrt[3]/2}}, 1/5],
            {x, -2, 2}, {y, -2, 2}, Exclusions -> None, PlotPoints -> 75]

{DensityPlot3D[lattice[{x, y, z}, 1, LatticeData["BodyCenteredCubic", "Basis"], 1/4],
               {x, 0, 2}, {y, 0, 2}, {z, 0, 2}, PlotPoints -> 75], 
 DensityPlot3D[lattice[{x, y, z}, 1, LatticeData["FaceCenteredCubic", "Basis"], 1/4],
               {x, 0, 2}, {y, 0, 2}, {z, 0, 2}, PlotPoints -> 75]} // GraphicsRow

Answer 2

Another approach would be to apply a transformation to a point in your original lattice to another lattice with orthogonal primitive vectors of unit length. One can then more easily find the nearest lattice coordinate there, thereby also finding the coefficients of the nearest lattice coordinate in the original space:

NearLat[x_, a_] := Total[a*Round[x.Inverse[a]]]
PWLat[x_, a_, V0_, r_] := Piecewise[{{V0, Norm[x - NearLat[x, a]] < r}}, 0]