4
$\begingroup$

I would like to get the area formed by two equations and the volume of the solid formed by this area around the Y axis.

Solve[x^2==6x-2x^2,x]

{{x->0},{x->2}}

Plot[{x^2,6x-2x^2},{x,0,2}]

enter image description here

I tried to use this idea but did not succeed;

Intersection Volume

$\endgroup$
3
$\begingroup$

I propose another way. You can use DiscretizeRegion to create a region from the ParametricRegion. Then, calculate the volume:

\[ScriptCapitalR]1 = 
 DiscretizeRegion[
 ParametricRegion[{{x, y, z},6 Sqrt[x^2 + y^2] - 2 (x^2 + y^2) > z && x^2 + y^2 <= 4 &&x^2 + y^2 <= z && z >= 0}, {{x, -4, 4}, {y, -4, 4}, {z, 0, 5}}],
 MaxCellMeasure -> #, ImageSize -> Small] & /@ {Automatic,0.1, 0.01,0.0005};
 vols1 = Volume[\[ScriptCapitalR]1[[#]]] & /@ Range[4];
 Row@(Labeled[\[ScriptCapitalR]1[[#]],Style["Volume = " <> ToString[vols1[[#]]], 12, FontFamily -> "Times New Roman"], Top]&/@ Range[4])

enter image description here

or use BoundaryDiscretizeRegion:

\[ScriptCapitalR]2 = 
 BoundaryDiscretizeRegion[
 ParametricRegion[{{x, y, z},6 Sqrt[x^2 + y^2] - 2 (x^2 + y^2) > z && x^2 + y^2 <= 4 &&x^2 + y^2 <= z && z >= 0}, {{x, -4, 4}, {y, -4, 4}, {z, 0, 5}}],
 MaxCellMeasure -> #, ImageSize -> Small] & /@ {Automatic,0.1, 0.01,0.0005};
 vols2 = Volume[\[ScriptCapitalR]2[[#]]] & /@ Range[4];
 Row@(Labeled[\[ScriptCapitalR]2[[#]],Style["Volume = " <> ToString[vols2[[#]]], 12, FontFamily -> "Times New Roman"], Top]&/@ Range[4])

enter image description here

In both cases, the value of the calculated volume, and obviously the appearance, depends on the value of the option MaxCellMeasure, as can be deduced from the plots.

It seems that BoundaryDiscretizeRegion has a greater accuracy.

The volume can be calculated directly from ParametricRegion, which is more exact, and compared to previous values:

NestList[N,Volume[ParametricRegion[{{x, y, z}, 
6 Sqrt[x^2 + y^2] - 2 (x^2 + y^2) > z && x^2 + y^2 <= 4 && x^2 + y^2 <= z && z >= 0},
{{x, -4, 4}, {y, -4, 4}, {z, 0, 5}}]],1]

(*{8 \[Pi], 25.1327}*)
| improve this answer | |
$\endgroup$
4
$\begingroup$

The area is simply given by

Integrate[ 6x - 2x^2 - x^2, {x, 0, 2}]
(* 4 *)

Using the cylinder method, the volume is given by

2 Pi*Integrate[x*Abs[6 x - 2 x^2 - x^2], {x, 0, 2}]
(* 8 Pi *)

You can also get the area with Area[ImplicitRegion[x^2 <= y <= (6 x - 2 x^2), {x, y}]]. For the volume, I would start by plotting the region with RevolutionPlot3D[6 x - 2 x^2 - x^2, {x, 0, 2}]. There a many posts about this on the website.

| improve this answer | |
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.