2
$\begingroup$

I am giving a presentation with several Manipulates and I would like to enlarge the animation control font size. By default it's quite small. For example, the code:

Manipulate[Plot[Sin[a z], {z, -1, 1}], {a, -1, 1}]

when the animation control is selected, gives the value of "a" in a small font size.

I can't seem to figure out how to enlarge the font for this and I was wondering if someone could help me.

Thanks Dominic

$\endgroup$
  • $\begingroup$ You can do it with BaseStyle thus: Manipulate[Plot[Sin[a z], {z, -1, 1}], {a, -1, 1, BaseStyle -> {FontSize -> 20}}]. But the input field does not resize to show the whole text of the number. $\endgroup$ – Michael E2 Oct 13 '17 at 21:14
2
$\begingroup$
Manipulate[
  Plot[Sin[a z], {z, -1, 1}, 
  PlotLabel -> Framed[StringForm["a=``", a]], 
  LabelStyle -> 16], {{a, -1, Style["a", 16]}, -1, 1}]

enter image description here

$\endgroup$
  • $\begingroup$ Thanks. But that only changes the font size for the label "a" What I would like to do is change the font size for the value of "a" when the user presses the animation control button. $\endgroup$ – Dominic Oct 13 '17 at 10:39
  • $\begingroup$ You can show it with the plot. Check the new answer. $\endgroup$ – Sumit Oct 13 '17 at 15:26
  • $\begingroup$ That's it guys. Thanks. Nice code! You guys have been a big help here helping me get my presentation ready for the tech conference next week. Will remember to acknowledge your help. This really is the place to get what I think is first-class help in Mathematica! :) $\endgroup$ – Dominic Oct 14 '17 at 7:46
2
$\begingroup$

You can change the default value of the option DefaultLabelStyle:

Options[Manipulate, DefaultLabelStyle]

{DefaultLabelStyle -> "ManipulateLabel"}

CurrentValue[{StyleDefinitions, "ManipulateLabel"}]

{ShowStringCharacters -> False, NumberMarks -> False,
FontFamily :> CurrentValue["PanelFontFamily"],
FontSize :> CurrentValue["PanelFontSize"] - 1, FontWeight -> "Plain"}

Define your new style

newDefaultLabelStyle = {ShowStringCharacters -> False, 
   NumberMarks -> False, FontFamily :> "Old English Text MT", 
   FontSize :> CurrentValue["PanelFontSize"] + 10, 
   FontWeight -> "Plain"};

Row[{Manipulate[Plot[Sin[ABCDEF  z], {z, -1, 1}], {ABCDEF, -1, 1}], 
  Manipulate[Plot[Sin[ABCDEF z], {z, -1, 1}], {ABCDEF, -1, 1}, 
   DefaultLabelStyle -> newDefaultLabelStyle]}]

enter image description here

$\endgroup$
  • 2
    $\begingroup$ +1 for not using Comic Sans as your example font. $\endgroup$ – bobthechemist Oct 13 '17 at 16:18
  • 1
    $\begingroup$ @bob, not that i didn't think about it:) $\endgroup$ – kglr Oct 13 '17 at 16:26

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.