Engineering a colour scale for MatrixPlot

Question

I am trying to find the best way to plot my data. I have a 2D list of scalar coefficients (rational numbers) whose value lies between 0 and 1 (being rational, they can be 0,..., 0.01,... 0.999,..., 1). I want to plot the amplitude of these coefficients in 2D and use a colour function to indicate their amplitude.

I think the best way to do this is to use

MatrixPlot[]

with options

ColorFunction -> "MyPersonalScheme"

and (possibly?)

ColorFunctionScaling -> True

In essence, my question is the following:

"How can I engineer a color scheme, "MyPersonalScheme", so that a coefficient of amplitude 0 is plotted in white, and a coefficient of amplitude 1 is plotted in red (and have a 'hue' of colour from white to red for amplitudes in between)?"

Thanks a lot in advance for your help!

Answer 1

In general, one uses Blend[] to construct custom color schemes.

Let's start with a concrete example:

BlockRandom[SeedRandom[42]; (* for reproducibility *)
            mat = RandomReal[1, {50, 50}]];

Here is how to use Blend[] with ArrayPlot[]:

ArrayPlot[mat, ColorFunction -> (Blend[{White, Red}, #] &), ColorFunctionScaling -> False]

(Something similar could be done for MatrixPlot[], but you might want to be aware that it downsamples by default.)

---

In fact, since one of your colors is White, there is an even simpler way to generate the same plot, using Lighter[]:

ArrayPlot[mat, ColorFunction -> (Lighter[Red, 1 - #] &), ColorFunctionScaling -> False]

---

Finally, the simplest method for this case would be the direct use of RGBColor[]:

ArrayPlot[mat, ColorFunction -> (RGBColor[1, 1 - #, 1 - #] &),
          ColorFunctionScaling -> False]

Answer 2

Let us denote your colour function by cf. Then MatrixPlot will use cf[0.5] for zero, colour function values in the range 0.5-1.0 for positive elements and values in the range 0.0-0.5 for negative elements.

This means that out of the built-in colour functions, those are most suitable for use with MatrixPlot which are symmetric to the middle, e.g. GreenPinkTones, MintColors, ThermometerColors, RedGreenSplit, LightTemperatureMap, TemperatureMap, etc.

If you create your own colour function, make it like this too. For example:

ColorFunction -> (Blend[{Blue, White, Red}, #] &)

@J.M. took a different approach: he set ColorFunctionScaling -> False, which asks MatrixPlot to pass the matrix values to the colour function without any scaling.

---

Example:

cfun = Blend[{Blue, White, Red}, #] &;

n = 200;
MatrixPlot[
 SparseArray[RandomInteger[{1, 20}, {n, 2}] -> RandomReal[{-1, 2}, n]],
 ColorFunction -> cfun
 ]

This is the colour function:

LinearGradientImage[cfun, {360, 36}]