2
$\begingroup$

Does anyone know why I just get the input back?

     DSolve[D[u[x, y, z], x]*x*(z - 2*y^2) + D[u[x, y, z], y]*y*
                 (z - y^2 - 2*x^3) == z*(z - y^2 - 2*x^3), 
                 u[x, y, z], {x, y, z}]

I've obtained the two first integrals of the PDE analytically but the third is tricky so I thought I'd ask Mathematica.

$\frac{dz}{0}$ implies $z=C_1$

$\frac{y^{-1}dy+z^{-1}du}{0}=\frac{d(\log y+z^{-1}u)}{0}$ implies $\log y+\frac{u}{z}=C_2$

https://math.stackexchange.com/questions/2429541/how-to-solve-a-quasi-linear-pde

$\endgroup$
  • $\begingroup$ Are you sure this is a "quasi-linear" PDE? Also, what do you mean by dividing by $0$? I don't understand the maths, and their relationship with the Mathematica question. $\endgroup$ – anderstood Sep 14 '17 at 18:08
  • $\begingroup$ All the first derivatives appear linearly meaning it is quasi-linear. The notation is often used but it just means that $z$ is a first integral of the system. So the solution should be $F(z,e^\frac{u}{z}+y,?)=0$ $\endgroup$ – Ivor Denham-Dyson Sep 14 '17 at 18:29
  • $\begingroup$ Thanks for the explanations. Using the definition of reference.wolfram.com/language/tutorial/… it seems to me your PDE is simply linear. Anyway that does not answer the question. $\endgroup$ – anderstood Sep 14 '17 at 18:35
  • $\begingroup$ Sure thing! Yes, linear sorry. Wondered if it wasnt one of those common pitfalls :) $\endgroup$ – Ivor Denham-Dyson Sep 14 '17 at 18:38
4
$\begingroup$

Because z enters into the PDE only as a parameter, it is convenient (but not necessary) to rewrite the PDE as

D[u[x, y], x]*x*(z - 2*y^2) + D[u[x, y], y]*y*(z - y^2 - 2*x^3) == z*(z - y^2 - 2*x^3)

This equation, if it can be solved, should be solved by the method of characteristics, as the OP began to do in the question. Define in the usual way,

p = x (-2 y^2 + z);
q = y (-2 x^3 - y^2 + z);
r = z (-2 x^3 - y^2 + z);

Then, two equations determining the characteristics are

D[u[x, y], x] - r/p == 0;
D[u[x, y], y] - r/q == 0;

However, the results of solving these characteristic equations is meaningful only if the equations are consistent; i.e., if

Simplify[D[D[u[x, y], x] - r/p, y] == D[D[u[x, y], y] - r/q, x]]

is True. In fact, the result is

(* (y (4 x^3 - z) z)/(x (2 y^2 - z)) == 0 *)

Hence, the characteristic equations are not, in general, consistent, just as observed by user64494, using Maple.

The equations are, however, consistent for z == 0, in which case the PDE can be solved. Setting z -> 0 in the PDE and dividing out a common factor of y then gives,

D[u[x, y], x]*x*(z - 2*y^2) + D[u[x, y], y]*y*(z - y^2 - 2*x^3) == 
    z*(z - y^2 - 2*x^3) /. z -> 0;
Simplify[#/y & /@ %]

(* (2 x^3 + y^2) D[u[x, y], x] +2 x y D[u[x, y], y] == 0 *)

which can be solved by the method described in Sec 2.2 of the article by Scott Sarra, based on solving its characteristic equation.

FullSimplify[DSolve[D[x[y], y] == ((p/q) /. {z -> 0, x -> x[y]}), x[y], y]]

(* {{x[y] -> (2 3^(1/3) C[1] + 2^(1/3) (9 y^2 + Sqrt[81 y^4 - 12 C[1]^3])^(2/3))/
     (6^(2/3) (9 y^2 + Sqrt[81 y^4 - 12 C[1]^3])^(1/3))}, ...}} *)

The second and third solutions are complex and, therefore, not useful for the real-valued PDE. u[x, y] is by this method an arbitrary function of C[1], expressed as a function of x and y:

Solve[%[[1, 1]] /. Rule -> Equal, C[1]] /. x[y] -> x

(* {{C[1] -> 0}, {C[1] -> (x^3 - y^2)/x}} *)

The first root corresponds to u[x, y] constant, which indeed does satisfy the z == 0 PDE. The second root corresponds to

u[x, y] -> c[(x^3 - y^2)/x]

where c is an arbitrary function of its argument. To verify that this final result is correct, substitute it back into the PDE.

Unevaluated[(2 x^3 + y^2) D[u[x, y], y] + 2 x y D[u[x, y], x] == 0] 
    /. u[x, y] -> c[(x^3 - y^2)/x];
% // Simplify

(* True *)

In summary, the original PDE has no solution unless z == 0. When z does vanish, u[x, t] is an arbitrary function of (x^3 - y^2)/x.

|improve this answer|||||
$\endgroup$
  • $\begingroup$ Thank you for such a detailed analysis! $\endgroup$ – Ivor Denham-Dyson Oct 17 '17 at 20:49
1
$\begingroup$

Maple 2017.2 outputs: Warning: System is inconsistent . See here: enter image description here

|improve this answer|||||
$\endgroup$
  • $\begingroup$ Thank-you, its a tutorial question. I guess these things happen. $\endgroup$ – Ivor Denham-Dyson Sep 14 '17 at 18:50
  • $\begingroup$ This answer would be more interesting if it explained the inconsistency. $\endgroup$ – anderstood Sep 14 '17 at 19:30
  • $\begingroup$ @anderstood: The execution of the above code at printlevel:=25 shows Maple uses differential algebra tools to this end. I am not a specialist in this field so I can say nothing. You may ask your questions in mapleprimes.com. $\endgroup$ – user64494 Sep 14 '17 at 19:48
  • 1
    $\begingroup$ @anderstood The characteristic equations associated with the PDE are inconsistent in that their cross derivatives are not equal. $\endgroup$ – bbgodfrey Sep 15 '17 at 4:39

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.