Multi-coloured tree plot

Question

I am trying to create a multi-coloured tree plot (Mathematica 9) where each branch is coloured according to its parent node value. For example, for a tree plot with three nodes, n1, n2 and n3, coming from a single parent node (n0), the children nodes of n1 should be red & n2 and n3 should be green.

TreePlot[nodes, EdgeRenderingFunction -> ({Red, Line[#1]} &), 
 VertexRenderingFunction -> (Inset[
     Row[{If[Last[#2] > 3, Rotate[Last[#2], 90 Degree], 
        Last[#2]]}], #1, Background -> White] &)]

I am using the EdgeRenderingFunction for this within the following expression which will render the edges of the tree plot. The problem, I think, is that the If statement is not evaluated straight away and so the compiler does not recognise the first option (contained within the If statement) as a relevant one. As you can see I'm trying to create a tree plot with red and green branches.

TreePlot[nodes, 
 EdgeRenderingFunction -> ({If[Last[#2] == 1, Red, Green], 
     Line[#1]} &), 
 VertexRenderingFunction -> (Inset[
     Row[{If[Last[#2] > 3, Rotate[Last[#2], 90 Degree], 
        Last[#2]]}], #1, Background -> White] &)]

The error message I get is:

If is not a Graphic Primitive or Directive

Thanks for your time in helping me with this.

Answer 1

The problem seems to be at least partially due to how you reference the arguments of EdgeRenderingFunction. We can label the edges with Last[#2] to see what we're working with:

nodes = {{0} -> {0, 1}, {0} -> {0, 2}, {0} -> {0, 3}, {0, 1} -> {0, 1, 4}, {0, 1} -> {0, 1, 5}, {0, 1} -> {0, 1, 6}, 
  {0, 1} -> {0, 1, 7}, {0, 1} -> {0, 1, 8}};
TreePlot[nodes, 
 EdgeRenderingFunction -> ({Line[#1], 
     Inset[Last[#2], Mean[#1], Automatic, Automatic, #[[1]] - #[[2]], 
      Background -> White]} &), 
 VertexRenderingFunction -> (Inset[
     Row[{If[Last[#2] > 3, Rotate[Last[#2], 90 Degree], 
        Last[#2]]}], #1, Background -> White] &)]

So none of these are ever going to be 1. You could, of course, use these for your colouring. You could also use the values in First[#2]:

TreePlot[nodes, 
 EdgeRenderingFunction -> ({Line[#1], 
     Inset[First[#2], Mean[#1], Automatic, Automatic, #[[1]] - #[[2]],
       Background -> White]} &), 
 VertexRenderingFunction -> (Inset[
     Row[{If[Last[#2] > 3, Rotate[Last[#2], 90 Degree], 
        Last[#2]]}], #1, Background -> White] &)]

You should be able to use any of these values to colour the edges however you want. For example, using #2[[1, -1]] for your condition gives:

TreePlot[nodes, 
 EdgeRenderingFunction -> ({If[#2[[1, -1]] == 1, Red, Green], 
     Line[#1]} &), 
 VertexRenderingFunction -> (Inset[
     Row[{If[Last[#2] > 3, Rotate[Last[#2], 90 Degree], 
        Last[#2]]}], #1, Background -> White] &)]

Answer 2

You code uses rules for edge styles, e.g.:

func[elist_, pn_, col_] := 
 Module[{rules = 
    MapThread[ed_[#1, x_] :> Style[ed[#1, x], #2] &, {pn, col}]},
  elist /. rules]

For example:

TreeGraph[
 func[{0 -> 1, 0 -> 2, 1 -> 3, 1 -> 4, 2 -> 5, 2 -> 6}, {0, 1, 
   2}, {Red, Green, {Purple, Thick, Dashed}}]]

Answer 3

There are simpler ways to do this. I do not have Mathematica 9 around, but I think this should work.

First, I recommend representing trees as directed graphs. This way the identity of the root vertex is already encoded. IGDirectedTree from IGraph/M is useful for this (Mathematica 10.0+ only), otherwise you can do a BreadthFirstScan.

Consider this directed tree:

tree = Graph@{1 -> 2, 2 -> 3, 1 -> 4, 1 -> 5, 1 -> 6, 2 -> 7, 2 -> 8, 
    4 -> 9, 2 -> 10, 2 -> 11, 1 -> 12, 12 -> 13, 2 -> 14, 13 -> 15, 
    2 -> 16, 2 -> 17, 9 -> 18, 4 -> 19, 11 -> 20};

Now simply use patterns to select a set of edges to colour:

Graph[tree,
 VertexShapeFunction -> "Name",
 EdgeStyle -> {1 \[DirectedEdge] _ -> Red, 2 \[DirectedEdge] _ -> Blue, 4 \[DirectedEdge] _ -> Green, 12 \[DirectedEdge] _ -> Orange}
 ]

Having a directed tree was useful because we could easily distinguish "down-edges" (away from the root) from "up-edges" (towards the root).

If you do not want the arrowheads displayed, add

EdgeShapeFunction -> "Line",
PerformanceGoal -> "Quality"

Like this:

Graph[tree,
 VertexShapeFunction -> "Name",
 EdgeStyle -> {Thick, (1 \[DirectedEdge] _) -> Red, 2 \[DirectedEdge] _ -> Blue, 4 \[DirectedEdge] _ -> Green, 12 \[DirectedEdge] _ -> Orange},
 EdgeShapeFunction -> "Line",
 PerformanceGoal -> "Quality"
]