0
$\begingroup$

I wanted to solve the inequality

-1 < 3/2 π*Sin[αa]/αa + Cos[αa] < 1 

for αa in range

-6 π < αa < 6 π 

but using FindInstance produces only one value, not the range of values for which the inequality is satisfied.


I tried the above method but it works only if $\alpha a$ is removed from the denominator. As can be seen from the screenshot.

$\endgroup$
  • $\begingroup$ Vishal, please do not use answers to add information to your question. Edit it instead the next time. $\endgroup$ – J. M. will be back soon Sep 7 '17 at 11:02
3
$\begingroup$

Use Reduce

ineq = Reduce[{
    -1 < 3/2 π*Sin[αa]/αa + Cos[αa] < 1,
    -6 π < αa < 6 π}, αa] // N

(*  -18.8496 < αa < -16.2718 || -15.708 < αa < -13.2498 || 
-12.5664 < αa < -10.2841 || -9.42478 < αa < -7.4154 || 
-6.28319 < αa < -4.71239 || -3.14159 < αa < -2.2505 || 
 2.2505 < αa < 3.14159 || 4.71239 < αa < 6.28319 || 
 7.4154 < αa < 9.42478 || 10.2841 < αa < 12.5664 || 
 13.2498 < αa < 15.708 || 16.2718 < αa < 18.8496  *)

Plot[{1, 3/2 π*Sin[αa]/αa + Cos[αa], -1},
 {αa, -6 π, 6 π}, AspectRatio -> 1,
 PlotLegends -> Placed["Expressions", {.77, .6}]]

enter image description here

EDIT:

rgn = ImplicitRegion[-1 < 
     3/2 π*Sin[αa]/αa + Cos[αa] < 
     1 && -6 π < αa < 6 π && -1 < y < 1, {αa, 
    y}];

Show[
 Plot[{1, 
   3/2 π*Sin[αa]/αa + 
    Cos[αa], -1}, {αa, -6 π, 6 π}, 
  AspectRatio -> 1, PlotLegends -> Placed["Expressions", {.77, .6}]],
 RegionPlot[rgn]]

enter image description here

$\endgroup$
  • $\begingroup$ I tried with Reduce but that is not working. It's showing "Reduce::nsmet: This system cannot be solved with the methods available to Reduce" and "Reduce::inex: Reduce was unable to solve the system with inexact coefficients or the system obtained by direct rationalization of inexact numbers present in the system. Since many of the methods used by Reduce require exact input, providing Reduce with an exact version of the system may help".Kindly help me. I am new to Mathematica. $\endgroup$ – Vishal Sep 6 '17 at 13:19
  • $\begingroup$ @Vishal - the above works for me with v11.1.1. Without knowing what version you used and what you entered, I cannot help you. $\endgroup$ – Bob Hanlon Sep 6 '17 at 14:36
  • $\begingroup$ I am using Mathematica Student Edition Version 11.0. I entered the same thing as was written in the answer. $\endgroup$ – Vishal Sep 6 '17 at 16:01
  • $\begingroup$ @Vishal - when you say "entered" did you retype it or just copy & paste? The latter is more reliable. Try starting with a fresh kernel. You may have some old definition laying around. $\endgroup$ – Bob Hanlon Sep 6 '17 at 16:29
  • $\begingroup$ yes, It is working on Mathematica 11.2. Thank you. $\endgroup$ – Vishal Dec 20 '17 at 4:48

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.