Question: Why can't Mathematica calculate this limit in this way? And what can I do to fix it?

Limit[Sum[2/n (1 + (2 i - 1)/n)^(1/3), {i, 1, n}], n -> \[Infinity]] //N

Of course this limit is a Riemann-Sum, so it can also be represented by:

Integrate[(1 + x)^(1/3), {x, 0, 2}] // N

Finally, I noticed from another question that this does work:

Limit[Sum[Sin[a + x*(k/n)]*(x/n), {k, 1, n}], n -> Infinity]

But what is the essential difference with my code?

  • 1
    $\begingroup$ Sum and Limit are evaluated separately. In the first case Sum cannot be evaluated for arbitrary n. In the second, it can. $\endgroup$
    – Szabolcs
    Commented Sep 3, 2017 at 21:00
  • 1
    $\begingroup$ You can try Needs["NumericalCalculus`"]; NLimit[Sum[..], n -> \[Infinity]] -- it gives exactly the same answer as Integrate[..] // N. $\endgroup$
    – Michael E2
    Commented Sep 3, 2017 at 21:08
  • 4
    $\begingroup$ Try Limit[Sum[2/n CubeRoot[1 + (2 i - 1)/n], {i, 1, n}], n -> \[Infinity]] $\endgroup$
    – LouisB
    Commented Sep 3, 2017 at 22:43
  • 1
    $\begingroup$ @LouisB Why does CubeRoot work?! $\endgroup$ Commented Sep 4, 2017 at 7:26
  • $\begingroup$ I do not know why CubeRoot works and Power[... , 1/3] does not. I try to use the Surd function for roots. See this question about n-th roots and this question about real roots for more information. $\endgroup$
    – LouisB
    Commented Sep 4, 2017 at 8:31

1 Answer 1


In order for Mathematica to be able to compute the limit of a sum, it (usually) needs to be able to first compute the sum itself. In this case, this is failing to do so when using Power but not when using the Surd. The reason is that, in general, you can't split the fraction inside the root to combine the $\frac{1}{n}$ in the first term with the $\frac{1}{n^{1/3}}$ in the second term. Under the assumptions of what $n$ is in your sum, however, this is valid, and if you simplify the expression using appropriate assumptions, then both Sum and Limit will succeed:

Simplify[2/n (1 + (2 i - 1)/n)^(1/3), n>0]
(* (2 (-1 + 2 i + n)^(1/3))/n^(4/3) *)

Limit[Sum[%, {i, 1, n}], n -> Infinity]    
(* 3/4 (-1 + 3 3^(1/3)) *)

(Note that in fact we know that $n\geq1$ or the sum is empty, but it is sufficient that $n$ is positive in the simplification step). It is a small bug that Sum doesn't recognize this automatically, and I have filed it for the developer to fix.

As for why Surd and CubeRoot work in this case. Since they are by definition functions from reals to reals (and in particular, do not use the principle root), it is in fact the case that $ \frac{\sqrt[3]{f(n)}}{n} = \sqrt[3]{\frac{f(n)}{n^3}}$. So Sum doesn't have to check any validity conditions and succeeds.


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.