5
$\begingroup$

In order to obtain a failure probability of an event, I need to integrate the PDF[BinormalDistribution[{0, 0}, {2, 1}, 0], {x, y}] over a region. In my case this region is defined by the following limit state function: gx[x_, y_] := (((y + 4)/2)^2 + ((x + 4)/3)^2 - 2).

gx[x_, y_] := (((y + 4)/2)^2 + ((x + 4)/3)^2 - 2)
cplot = ContourPlot[{PDF[BinormalDistribution[{0, 0}, {2, 1}, 0], {x, y}]}, {x, -4, 4}, {y, -4, 4}, Contours -> 10];
rgplot= RegionPlot[gx[x, y] < 0, {x, -4, 4}, {y, -4, 4}];
Show[cplot , rgplot]

enter image description here

How to compute this integral? I've tried this:

NIntegrate[
 PDF[BinormalDistribution[{0, 0}, {1, 1}, 0], {x, y}], {x, -4, 
  2/3 (-6 + Sqrt[2 - 8 x - x^2])}, {y, -4, 
  1/2 (-8 + 3 Sqrt[-8 - 8 y - y^2])}]

but it doesn't work.

$\endgroup$
5
$\begingroup$

Like this:

reg = ImplicitRegion[gx[x, y] < 0, {{x, -4, 4}, {y, -4, 4}}];
NIntegrate[
 PDF[BinormalDistribution[{0, 0}, {1, 1}, 0], {x, y}],
 Element[{x, y}, reg]
 ]

0.0100282

$\endgroup$
5
$\begingroup$

You can also do this:

NProbability[gx[x, y] < 0 && -4 < x < 4 && -4 < y < 4, {x, y} \[Distributed] 
    BinormalDistribution[{0, 0}, {1, 1}, 0]]

(* Out: 0.0100282 *)
$\endgroup$
2
$\begingroup$

With

pdf = PDF[BinormalDistribution[{0, 0}, {2, 1}, 0], {x, y}];
gx[x_, y_] := (((y + 4)/2)^2 + ((x + 4)/3)^2 - 2)

(there's {2,1} in the question, but {1,1} was employed in the other two answers)

either

NIntegrate[pdf Boole[gx[x, y] < 0], {x, -4, 4}, {y, -4, 4}]

0.0209579

or

NIntegrate[pdf Boole[gx[x, y] < 0], {x, -∞, ∞}, {y, -∞, ∞}]

0.0234098

depending on the need.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.