Express as Meijer G function

Question

Let $\operatorname{E}_1(z)=-\operatorname{Ei}(-z)$ where $\operatorname{Ei}(z)$ is the exponential integral. Can the function $$f(x;a)=\int_{a}^{\infty}\frac{\mathrm{E}_1(t)}{x+t}\,dt,\quad x\ge0,$$ where $a>0$ is a fixed parameter, be expressed as a Meijer $G$ function?

Answer 1

In your general case, it doesn't look like the type that can be expressed as a $G$ function. To wit, note that your integral is expressible as a Mellin convolution of $\operatorname{\theta}(t-a)\operatorname{\mathit E}_1(t)$ and $\frac1{1+t}$. The latter function has a nice Mellin transform entirely in terms of gamma functions:

MellinTransform[1/(1 + t), t, s] == Gamma[s] Gamma[1 - s] // FullSimplify
   True

However,

Assuming[a > 0, 
         MellinTransform[HeavisideTheta[t - a] ExpIntegralE[1, t], t, s]] // FullSimplify
   (-a^s E^-a - a^s s Gamma[0, a] + Gamma[1 + s, a])/s^2

involves the incomplete gamma function. Recalling that 1. a Mellin convolution of the product of two functions is the product of the transforms, and 2. Meijer $G$ functions are inverse Mellin transforms of gamma function ratios, your original convolution integral does not seem to be expressible as a $G$ function.

---

If $a=0$, however, things are much nicer, since:

MellinTransform[ExpIntegralE[1, t], t, s] == Gamma[s]^2/Gamma[s + 1] // FullSimplify
   True

and so

InverseMellinTransform[Gamma[s]^2/Gamma[s + 1] Gamma[s] Gamma[1 - s], s, x]
   MeijerG[{{0}, {1}}, {{0, 0, 0}, {}}, x]

or in $\LaTeX$,

$$G_{2,3}^{3,1}\left(x\middle|{{0,1}\atop{0,0,0}}\right)$$

Compare:

With[{x = 5}, NIntegrate[ExpIntegralE[1, t]/(x + t), {t, 0, ∞}, WorkingPrecision -> 25]]
   0.1838089114612967395147973

With[{x = 5}, N[MeijerG[{{0}, {1}}, {{0, 0, 0}, {}}, x], 25]]
   0.1838089114612967395147973