Simplify Binomial Function

Question

The following input

Assuming[
   (n ∈ Integers) && (n > 0) && (k ∈ Integers) && (k >= 0) && (k <= n), 
   FullSimplify[Binomial[n, k]/Binomial[n, k + 1]]
]

returns

Binomial[n,k]/Binomial[n,k+1]

Why does it not give

(k+1)/(n-k)

and how do I make it do this?

J. M.'s persistent exhaustion · Accepted Answer · 2013-06-13 11:30:32Z

14

Try using FunctionExpand:

FunctionExpand[Binomial[n, k]/Binomial[n, 1 + k]]    
  (1 + k)/(-k + n)

Mathematica's understanding of what is simple is based on leaf count and can be unintuitive at times.

121k11 gold badges376 silver badges555 bronze badges

answered Nov 29, 2012 at 0:22

Searke

4,38418 silver badges23 bronze badges

$\begingroup$ perfect, thanks Searke $\endgroup$
– Lucas
Nov 29, 2012 at 0:24
1

$\begingroup$ LeafCount indeed gets you a complexity of 11 for both terms. Using the written size of the expression with ComplexityFunction -> (StringLength@ToString[#] &)] still yields the same result, though FullSimplify now delivers the version that the OP wants. $\endgroup$
– Sjoerd C. de Vries
Nov 29, 2012 at 16:05
$\begingroup$ Somehow, I have never considered StringLength as a ComplexityFunction until now. $\endgroup$
– Searke
Nov 29, 2012 at 16:06

Add a comment |

J. M.'s persistent exhaustion · Accepted Answer · 2013-06-13 11:31:07Z

10

Another way to proceed would be to make Binomial more expensive (or less simple) using a ComplexityFunction:

f[e_] := 100 Count[e, _Binomial, {0, Infinity}] + LeafCount[e]

FullSimplify[Binomial[n, k]/Binomial[n, k + 1], ComplexityFunction -> f]

gives

(1 + k)/(-k + n)

121k11 gold badges376 silver badges555 bronze badges

answered Nov 29, 2012 at 0:26

WalkingRandomly

4,0171 gold badge18 silver badges36 bronze badges

1

$\begingroup$ Sounds, erm, complex. But it is interesting and good to know. $\endgroup$
– Lucas
Nov 29, 2012 at 0:32
$\begingroup$ It is interesting, that Simplify[Binomial[n, k]/Binomial[n, 1 + k], ComplexityFunction -> f] with your definition for f gives Binomial[n, k]/Binomial[n, 1 + k]. It looks like Simplify does not try enough transformations of Binomial. $\endgroup$
– au700
Nov 29, 2012 at 0:34
1

$\begingroup$ Probably. You could perhaps find out using another recent Q+A of mine mathematica.stackexchange.com/questions/15321/… $\endgroup$
– WalkingRandomly
Nov 29, 2012 at 0:39
$\begingroup$ @WalkingRandomly It is overkill 100 Count..., 1 Count... is good enough, +1. $\endgroup$
– Artes
Nov 30, 2012 at 0:43

Add a comment |

2 Answers 2