I'm working with Options to change the look and feel of some generated Graphics by passing Options to several functions, one of them being Export[]. For example:

Options[myPlot] := {Resolution -> 325, Size -> 12, FileName -> "A", 
  PlotStyle -> Automatic};

myPlot[f_, opts : OptionsPattern[myPlot]] := Block[{fig},
(* ... some calculations here *)
fig = Plot[f[x], {x, -\[Pi], \[Pi]}, 
    Evaluate[FilterRules[{opts}, Options[Plot]]]];
fig = Show[fig, ImageSize -> OptionValue[Size]*72/2.54];+
Export[OptionValue[FileName] <> ".png", fig,  FilterRules[{opts}, Options[Export]]];

And using f[x_] := x^2 use the function as

 myPlot[f, Resolution -> 120, PlotStyle -> Red]

The Option to plot the function in Red is passed correctly to Plot but Resolution is not passed to Export. This is of course due to the fact that Options[Export] = {}.

My question is:

How can I still pass Options to Export (i.e. how to determine, which are available, if they are not written in Options[Export]?

And closely related:

How to do that on your own, i.e. now I defined PlotStyle to be an Option of myPlot, though it's only passed on, how can I pass Options, that I haven't given myself, without getting the message

OptionValue::nodef: "Unknown option PlotStyle for ...


1 Answer 1


Extraction of Export options

To extract the options for specific image export formats automatically, I really don't know an easy way. What you can do is to use Trace in combination with ExportString to investigate what Mathematica is doing. To make the next thing work you have to call e.g. ExportString["test", "GIF"]; for every format at least once:

ExportString["test", #]; & /@ {"PNG", "GIF", "BMP", "JPEG"}

System`ConvertersDump`exportOptions /@ {"PNG", "GIF", "BMP", "JPEG"}
{{"BitDepth", "ColorSpace", 
  "DataType"}, {"AnimationRepetitions", "Background", "FrameRate", 
  "TransitionEffect", "TransparentColor", 
  "UserInputFlag"}, {"BitDepth", "ColorSpace", "DataType", 
  "HorizontalResolution", "RLECompression", 
  "VerticalResolution"}, {"BitDepth", "ColorSpace"}}

which is unfortunately very distinct from the documentation. For some exporters you find for instance such stuff

 {Background -> None, ImageResolution -> Automatic, 
 ImageSize -> Automatic, "ImageTopOrientation" -> Top, 
 "ColorReductionPalette" -> 256, "ColorReductionDither" -> True, 
 "GlobalColorMap" -> True}

But how to find this automatically? I have no idea. Checkout this too


Setting up options for own functions

Say you want to setup a function which can take its own options, options of Plot and options of NMinimize. Furthermore, you want to specify some of the default option-values for Plot and NMinimize. You can set the function up and use it like follows:

Options[f] = {
   fopt1 -> Automatic,
   fopt2 -> True,
   PlotStyle -> Green,
   AccuracyGoal -> 1

f[x_, opts : OptionsPattern[{f, Plot, NMinimize}]] := Module[{},
  Print["Given Options usable by f only:", 
   FilterRules[{opts}, Options[f]]];
  Print["Given Options usable by Plot only:", 
   FilterRules[{opts}, Options[Plot]]];
  Print["Given Options usable by NMinimize only:", 
   FilterRules[{opts}, Options[NMinimize]]];

  Print["Defaultvalue for not specified options:" ];

Test case

f[x, fopt1 -> Full, PlotStyle -> Yellow, AccuracyGoal -> 42]
Given Options usable by f only:{fopt1->Full,PlotStyle->RGBColor[1,1,0],AccuracyGoal->42}
Given Options usable by Plot only:{PlotStyle->RGBColor[1,1,0]}
Given Options usable by NMinimize only:{AccuracyGoal->42}

Defaultvalue for not specified options:

And now you can pass any other option of Plot or NMinimize without a warning. But be carful, something like Method is an option for many functions and would be passed to each approapriate.

  • $\begingroup$ Already learned your last note the hard way when combining ListPointPLot3D and a ParametricPlot3D both using ColorFunction (used Complement[FilterRules[{opts}, Options[ListPointPlot3D]] , {ColorFunction}] to deal with that), to use ColorFunction to colour just surface. $\endgroup$
    – Ronny
    Nov 27, 2012 at 10:58
  • 1
    $\begingroup$ @Ronny In this case you can introduce your own ParamPlotColFunc and ListPointPlColFunc options and map then inside your implementation to the correct function. $\endgroup$
    – halirutan
    Nov 28, 2012 at 9:06
  • $\begingroup$ That is of course the good way to do it, the code in the comment above was just to illustrate how to exclude some Options. In a white list type Options limitation the best way is yours. $\endgroup$
    – Ronny
    Nov 28, 2012 at 9:57
  • $\begingroup$ As an answer to the extended version: Now, where i see, that it is quite complicated to get an automated way, maybe even @halirutan s way to introduce an own set of parameters that are passed down, might be a good idea to avoid too much work for the automated way. $\endgroup$
    – Ronny
    Nov 28, 2012 at 10:23
  • $\begingroup$ System`ConvertersDump`exportOptions seem a good function. But don't work v12.0 anymore... $\endgroup$
    – yode
    May 17, 2019 at 15:31

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.