Find the center of a circular specimen

Question

In order to automate the process of finding the Orientation of the pattern in an image, I would like to first find the center of a circular specimen. Original image can be downloaded here. My current progress and the results are described further on.

I can get some sort of circular shaped 2D object using the following set of commands: DeleteSmallComponents@Colorize@MorphologicalComponents[image], which results in

Using built-in ComponentMeasurements[] in the following code

pos = ComponentMeasurements[DeleteSmallComponents@  
  Colorize@MorphologicalComponents[image],  "BoundingDiskCenter"]

and plotting a point on an image with the code

PointPlot=ListPlot[{{pos[[1, 2, 1]], pos[[1, 2, 2]]}}, 
         PlotStyle -> Directive[Red, PointSize -> Medium]];
Show[{image, PointPlot}, ImageSize -> Full]

gives the center as:

As you can see, the point is not at exact center of the circle. I have tried using ImageCorrelation with the white disk on the black background, but I cannot manage to match the size of the specimen with the size of the disk. I apologize for bad code formatting, but I have no idea how to improve it.

Answer 1

Here's something you can try: First, find the coordinates of all the bright spots in the image:

img = Import["https://i.sstatic.net/8NPCs.jpg"];    
bin = MorphologicalBinarize[img];    
allPoints = Round@ComponentMeasurements[bin, "Centroid"][[All, 2]];

Then we calculate the convex hull of these points:

hull = ConvexHullMesh[allPoints];    
HighlightImage[bin, hull]

As you can see, there are a few outliers that "pull" the hull in the wrong direction. The easiest way to get rid of these outliers is to remove all the corners of the convex hull from the original point set, then calculate the convex hull again. (I think this algorithm is called "onion peeling" in Computational Geometry. Because it peels the outer layers of a point set one by one.)

If we do this a few times in a loop:

innerPoints = allPoints;
innerHull = hull;
onionLayers = Table[(
    innerPoints = 
     Complement[innerPoints, Round[MeshCoordinates[innerHull]]];
    innerHull = ConvexHullMesh[innerPoints]
    ), {n, 3}];

The "onion layers" look like this:

HighlightImage[bin, {Opacity[.2], hull, onionLayers}]

The isolated outliers are removed. So are a few of the "good" points, but they don't move the hull much, as they're packed close together.

You can then get the bounding disk of this hull using BoundingRegion:

HighlightImage[bin, {BoundingRegion[innerHull, "MinDisk"]}]

Answer 2

Something like the following seems to work decently well:

bin = Binarize@MorphologicalPerimeter@img

DeleteSmallComponents@Erosion[Closing[%, 40], 1];
centroid = MaximalBy[Values@ComponentMeasurements[%, {"Area", "Centroid"}], First][[1, 2]];

HighlightImage[bin, centroid]