Creating dataset from list of ragged associations with defaults for missing keys

Question

Given the ragged dataset in form of association of associations:

<|
  "r1" -> <|"a" -> 2, "b" -> 3          |>, 
  "r2" -> <|          "b" -> 5, "c" -> 6|>
|>

How do I construct a Dataset with missing keys set to Missing or default value 0?

Like

<|
  "r1" -> <|"a" -> 2, "b" -> 3  "c" -> 0|>, 
  "r2" -> <|"a" -> 0  "b" -> 5, "c" -> 6|>
|>

Of course, the actual dataset is very large and I need it in Dataset object

Answer 1

Given:

assoc = <| "r1" -> <|"a" -> 2, "b" -> 3          |>
         , "r2" -> <|          "b" -> 5, "c" -> 6|>
         |>;

... here is a way using KeyUnion:

AssociationThread[assoc // Keys, KeyUnion[assoc // Values, 0&]]

(* <| "r1" -> <|"a" -> 2, "b" -> 3, "c" -> 0|>
    , "r2" -> <|"a" -> 0, "b" -> 5, "c" -> 6|>
    |>
*)

The default value function 0& can be generalized to return a different value based upon the key which is passed as an argument. For example:

default["a"] := 999
default["c"] := -999

AssociationThread[assoc // Keys, KeyUnion[assoc // Values, default]]
(* <| "r1" -> <|"a" -> 2,   "b" -> 3, "c" -> -999|>
    , "r2" -> <|"a" -> 999, "b" -> 5, "c" -> 6   |>
    |>
*)

Answer 2

data = <|
  "r1" -> <|"a" -> 2, "b" -> 3|>,
  "r2" -> <|"b" -> 5, "c" -> 6|>
  |>
keys = Union @@ Map[Keys, data]  (* EDIT: ht Anton *)
f[a_Association] := Association[# -> Lookup[a, #, Missing[]] & /@ keys]
Dataset[f /@ data]