Laurent Series with Symbolic Powers

Question

I'm having trouble getting Mathematica to expand expressions in a Laurent series when the expansion parameter is raised to symbolic powers.

As an example, consider:

Assuming[{a > 0, c1 > 0, c2 > 0, c3 > 0}, Normal[Series[a^(-c2)/((a*c1)^(c2) + c3), {a, 0, 0}]]]

I want this to take $\frac{1}{a^{c_2}}\frac{1}{(a c_1)^{c_2}+c_3}$ and expand about $a=0$ to zeroth order in $a$.

The result should be $\frac{1}{c_3}\frac{1}{ a^{c_2}}-\frac{c_1^{c_2}}{c_3^2}$, but instead I just get back $\frac{1}{a^{c_2}}\frac{1}{(a c_1)^{c_2}+c_3}$ again. No expansion takes place at all. I.e. the result is:

a^(-c2)/((c1*a)^(c2) + c3)

Are there extra Assumptions that need to be added?

Answer 1

Series does not work with symbolic powers. Here is a simple example:

Series[x^n, {x, 0, 5}]

x^n

To see why, note that Series (when it works) evaluates to a SeriesData object:

Series[x, {x, 0, 1}] //InputForm

SeriesData[x, 0, {1}, 1, 2, 1]

Let's look at the SeriesData documentation:

WolframLanguageData["SeriesData","PlaintextUsage"]

"SeriesData[x, x0, {a0, a1, …}, nmin, nmax, den] represents a power series in the variable x about the point x0 . The ai are the coefficients in the power series. The powers of (x - x0) that appear are nmin / den, (nmin + 1) / den, …, nmax / den."

So, a SeriesData representation of $x^n$ would look something like:

SeriesData[x, 0, {1}, n, n+1, 1]

SeriesData::sdatn: Order specification n in SeriesData[x,0,{1},n,1+n,1] is not a machine-sized integer.

SeriesData[x, 0, {1}, n, 1 + n, 1]

which isn't supported. This is why a naive application of Series to your expression doesn't work.

One possibility is to just replace your variable with one whose powers are all explicit integers, and then use Series:

e = PowerExpand[
    a^(-c2)/((a*c1)^(c2) + c3) /. a -> z^(1/c2),
    Assumptions -> z>0 && c1>0 && c2>0 && c3>0
]

1/(z (c3 + c1^c2 z))

Now, we can use Series:

s = Series[e, {z, 0, 0}];
s //TeXForm

$\frac{1}{\text{c3} z}-\frac{\text{c1}^{\text{c2}}}{\text{c3}^2}+O\left(z^1\right)$

Convert back, after converting the Series object back to a normal expression:

r = Normal[s] /. z -> a^c2
r //TeXForm

-(c1^c2/c3^2) + a^-c2/c3

$\frac{a^{-\text{c2}}}{\text{c3}}-\frac{\text{c1}^{\text{c2}}}{\text{c3}^2}$