# The algebraic solution and numerical solutions for eigenvectors are different. Why?

I find that the algebraic solution for the Eigenvectors of a 3x3 matrix is not correct when compared to the numerical solution. I don't see why ?

Clear[a, b, c, d, q, z]
q = {{-a, b, 0},{a, -b - c, d},{0, c, -d}};
z = Eigenvectors[q];
a = 2;
b = 0.1;
c = 3;
d = 1;
MatrixForm[z]
MatrixForm[Eigenvectors[q]]

• The symbolic answer (z) is not the correct one. – stéphane Supplisson Jul 15 '17 at 10:43
• From "Details and Options" of Eigenvectors documentaion: "For approximate numerical matrices m, the eigenvectors are normalized. For exact or symbolic matrices m, the eigenvectors are not normalized." – jkuczm Jul 15 '17 at 13:37
• Thank you. Now I know why the symbolic and numeric answers are different. Still I don't know how to normalize z in a way that I could have a general eigenvector – stéphane Supplisson Jul 15 '17 at 15:41

There are several reasons. As jkuczm pointed out, symbolic eigenvectors are not normalized. Why? Simply because normalizing them symbolically would render the output unreadible while it would not provide any new information. This is the first reason.

The second one is the ordering of the eigenvectors. For numerical input, the eigenvectors are ordered such that their corresponding eigenvalues are ordered by their modulus in decending order. In general, it is not feasible to order symbolic eigenvalues by their modulus: It is just to complicated or it may be impossible without further knowledge about the occuring symbols.

The third reason is that there is no canonical direction for eigenvectors; even algorithms that return normalized eigenvectors may differ in the way of "distributing signs".

This all reflects that results returned by Eigenvectors represents certain vector spaces. If your input matrix has multiple eigenvalues then the respective eigenspaces have dimensions greater than one. In that case, there is no way at all to standardize the result and the best you can expect is to obtain just any basis for each eigenspace.

In your particular example, you can normalize and order your result by the following

Clear[a, b, c, d, q, z]
q = {{-a, b, 0}, {a, -b - c, d}, {0, c, -d}};
z = Eigenvectors[q];
\[Lambda] = Eigenvalues[q];
a = 2;
b = 0.1;
c = 3;
d = 1;
MatrixForm[Map[Normalize, z][[Ordering[-Abs[\[Lambda]]]]]]
MatrixForm[Eigenvectors[q]]


But as you can see, the eigenbases may still differ by sign.

• Thank you for your rational explanation. – stéphane Supplisson Jul 15 '17 at 20:08