Simplification fails for complex variables

Question

I ran into the problem that Mathematica's (full-) simplification does not replace

t Conjugate[t]

by

Abs[t]^2

In my case, I get pretty ugly expressions which greatly simplify when I replace the expressions manually. As an example:

FullSimplify[( 2 (-((Abs[a - b + Sqrt[(a - b)^2 + 4 t Conjugate[t]]]^2 + 
  4 t Conjugate[t])/(
 2 (a + b - 2 ω + Sqrt[(a - b)^2 + 4 t Conjugate[t]]))) + (
Abs[-a + b + Sqrt[(a - b)^2 + 4 t Conjugate[t]]]^2 + 
 4 t Conjugate[t])/(
2 (-a - b + 2 ω + 
   Sqrt[(a - b)^2 + 4 t Conjugate[t]]))))/((a - b) (Conjugate[a] -
  Conjugate[b]) + 4 t Conjugate[t] +   Sqrt[(a - b)^2 + 4 t Conjugate[t]]
Conjugate[Sqrt[(a - b)^2 + 4 t Conjugate[t]]]), {{a, 
b, ω} ∈ Reals, t ∈ Complexes}]

Does not yield any simplification. However, if I replace

t Conjugate[t] -> Abs[t]^2

or, if I change $t$ to be real, I find the desired result $\frac{b-\omega}{ |t|^2-(a-\omega)(b-\omega)}$

PS: I just realized this is appears to be the same problem as posted here: FullSimplify on complex numbers seems inconsistent. However I'd much appreciate a less "crazy" solution…

Answer 1

You can use ComplexExpand with a suitable TargetFunctions option and Simplify. Here is your expression:

expr = (2 (-((Abs[a - b + Sqrt[(a - b)^2 + 4 t Conjugate[t]]]^2 + 
        4 t Conjugate[t])/(2 (a + b - 2 ω + 
          Sqrt[(a - b)^2 + 4 t Conjugate[t]]))) + (Abs[-a + b + 
         Sqrt[(a - b)^2 + 4 t Conjugate[t]]]^2 + 
      4 t Conjugate[t])/(2 (-a - b + 2 ω + 
        Sqrt[(a - b)^2 + 4 t Conjugate[t]]))))/((a - b) (Conjugate[a] - 
    Conjugate[b]) + 4 t Conjugate[t] + 
 Sqrt[(a - b)^2 + 4 t Conjugate[t]] Conjugate[
   Sqrt[(a - b)^2 + 4 t Conjugate[t]]]);

Then, you can use:

Simplify[
    ComplexExpand[expr, t, TargetFunctions->{Abs}],
    (a | b | ω) ∈ Reals
]

(b - ω)/((a - ω) (-b + ω) + Abs[t]^2)