Finding Asymptotics for a Series

Question

How can I find a simple expression that's asymptotic to $\sum_{i=1}^{n-1}2^i/i$?

That is,

Sum[2^i/i,{i,1,n-1}].

According to https://reference.wolfram.com/language/example/AsymptoticBehaviorOfAFunction.html, I can use

mainTerm[expr /. x -> 1/x, x]

However, when I insert their example

mainTerm[(x^2+1)/(1+x), x]

the output I receive is exactly the same as the input instead of $x$.

Is there a command that will give the main term?

Answer 1

As @DanielLichtblau says, Mathematica can do the symbolic sum in terms of LerchPhi:

sum = Sum[2^i/i, {i, n}]

-I ([Pi] - I 2^(1 + n) LerchPhi[2, 1, 1 + n])

It seems that Mathematica can't do the asymptotic expansion:

Series[sum, {n, Infinity, 0}]

-I ([Pi] - I E^SeriesData[n, DirectedInfinity[1], { Log[2], Log[2]}, -1, 2, 1] LerchPhi[2, 1, 1 + n])

However, you can use EntityValue to figure out the asymptotics. Here is what EntityValue says about LerchPhi:

ev = Entity["MathematicalFunction", "LerchPhi"]["AsymptoticExpansions"];
ev //InputForm

(* {Function[{\[FormalZ], \[FormalS], \[FormalA]}, Inactivate[ConditionalExpression[
    LerchPhi[\[FormalZ], \[FormalS], \[FormalA]] \[Proportional] (-(1/\[FormalZ]))*Sum[1/((\[FormalA] - \[FormalK] - 1)^\[FormalS]*\[FormalZ]^\[FormalK]), 
        {\[FormalK], 0, Infinity}] + (Log[-\[FormalZ]]^(\[FormalS] - 1)/((-\[FormalZ])^\[FormalA]*(2*Gamma[\[FormalS]])))*
       (2*Pi*Csc[\[FormalA]*Pi] + (Gamma[\[FormalS]] - 1)*(PolyGamma[(1 + \[FormalA])/2] - 
          PolyGamma[\[FormalA]/2])) + (Log[-\[FormalZ]]^(\[FormalS] - 2)/((-\[FormalZ])^\[FormalA]*(2*Gamma[\[FormalS]])))*
       Sum[((2^(\[FormalK] + 1)/(\[FormalK] + 1))*(BernoulliB[\[FormalK] + 1, 1 - \[FormalA]/2] - 
            BernoulliB[\[FormalK] + 1, (1 - \[FormalA])/2]) + (-1)^\[FormalK]*(\[FormalS] - 1)*Gamma[\[FormalS]]*
           Pochhammer[2 - \[FormalS], \[FormalK]]*2^(-\[FormalK] - 1)*(Zeta[\[FormalK] + 2, \[FormalA]/2] - 
            Zeta[\[FormalK] + 2, (\[FormalA] + 1)/2]))/Log[-\[FormalZ]]^\[FormalK], {\[FormalK], 0, Infinity}], 
    (Abs[\[FormalZ]] -> Infinity) && Re[\[FormalA]] > 0 && Re[\[FormalS]] > 0]]], 
 Function[{\[FormalZ], \[FormalS], \[FormalA]}, Inactivate[ConditionalExpression[
    LerchPhi[\[FormalZ], \[FormalS], \[FormalA]] \[Proportional] (1/Gamma[\[FormalS]])*
      (Sum[((Gamma[\[FormalS], (\[FormalA] - \[FormalK] - 1)*Log[-\[FormalZ]]] - Gamma[\[FormalS]])/(\[FormalA] - \[FormalK] - 1)^\[FormalS])*
         \[FormalZ]^(-\[FormalK] - 1), {\[FormalK], 0, Infinity}] + (Log[-\[FormalZ]]^(\[FormalS] - 1)/((-\[FormalZ])^\[FormalA]*2))*
        (PolyGamma[(\[FormalA] + 1)/2] - PolyGamma[\[FormalA]/2] + 
         Sum[(Binomial[\[FormalS] - 1, \[FormalK]]*\[FormalK]!*(Zeta[\[FormalK] + 1, \[FormalA]/2] - 
             Zeta[\[FormalK] + 1, (\[FormalA] + 1)/2]))/(2^\[FormalK]*Log[-\[FormalZ]]^\[FormalK]), 
          {\[FormalK], 1, Infinity}])), (Abs[\[FormalZ]] -> Infinity) && Re[\[FormalA]] > 0 && 
     Re[\[FormalS]] > 0]]], Function[{\[FormalZ], \[FormalS], \[FormalA]}, 
  Inactivate[ConditionalExpression[LerchPhi[\[FormalZ], \[FormalS], \[FormalA]] \[Proportional] 
     1/((\[FormalA]^2)^(\[FormalS]/2)*(1 - \[FormalZ])) + 
      Sum[((((-1)^\[FormalK]*Pochhammer[\[FormalS], \[FormalK]])/\[FormalK]!)*PolyLog[-\[FormalK], \[FormalZ]])/\[FormalA]^\[FormalK], 
        {\[FormalK], 1, Infinity}]/(\[FormalA]^2)^(\[FormalS]/2), Abs[\[FormalA]] -> Infinity]]]} *)

It is the third expansion that is of interest. Let's extract it, and use it for the LerchPhi object:

asymp = Activate[
    ev[[3]][2, 1, n],
    ConditionalExpression | LerchPhi | Pochhammer | PolyLog | DirectedInfinity |
    Abs | Times | Power | Proportional
];
asymp /. \[FormalK] -> i //TeXForm

$\text{ConditionalExpression}\left[\Phi (2,1,n)\propto \frac{1}{\sqrt{n^2} (1+-2)}+\frac{\underset{i=1}{\overset{\infty }{\sum }}\frac{(-1)^i n^{-i} (1)_i \text{Li}_{-i}(2)}{i!}}{\sqrt{n^2}},\left| n\right| \to \infty \right]$

We are interested in the limit Abs[n] -> Infinity:

asymp = asymp /. _Rule -> True;
asymp /. \[FormalK] -> i //TeXForm

$\Phi (2,1,n)\propto \frac{1}{\sqrt{n^2} (1+-2)}+\frac{\underset{i=1}{\overset{\infty }{\sum }}\frac{(-1)^i n^{-i} (1)_i \text{Li}_{-i}(2)}{i!}}{\sqrt{n^2}}$

I will use the above relation to define:

lerchSeries[k_, n_] := Evaluate[Activate[asymp[[2]] /. Infinity->k]]

Let's compare the asymptotics of lerchSeries and LerchPhi[2, 1, n+1]:

z = 10`30^2;
LerchPhi[2, 1, z+1] //Chop
lerchSeries[10, z+1]

z = 10`30^3;
LerchPhi[2, 1, z+1] //Chop
lerchSeries[10, z+1]

z = 10`30^4;
LerchPhi[2, 1, z+1] //Chop
lerchSeries[10, z+1]

z = 10`30^5;
LerchPhi[2, 1, z+1] //Chop
lerchSeries[10, z+1]

-0.01010313809318820225350918612

-0.0101031380931847134629924527375

-0.00100100301307554573084602616

-0.00100100301307554573084602289673

-0.00010001000300130075054146877

-0.000100010003001300750541468773477

-0.0000100001000030001300075005

-0.0000100001000030001300075005410468

I think the agreement is pretty good. So, the asymptotics of the sum is:

sum /. LerchPhi[2, 1, n+1] -> lerchSeries[10, n+1] //TeXForm

$-i \left(\pi -i 2^{n+1} \left(\frac{-\frac{2}{n+1}-\frac{6}{(n+1)^2}-\frac{26}{(n+1)^3}-\frac{150}{(n+1)^4} -\frac{1082}{(n+1)^5}-\frac{9366}{(n+1)^6}-\frac{94586}{(n+1)^7}-\frac{1091670}{(n+ 1)^8}-\frac{14174522}{(n+1)^9}-\frac{204495126}{(n+1)^{10}}}{\sqrt{(n+1)^2}}-\frac{ 1}{\sqrt{(n+1)^2}}\right)\right)$

or:

Series[sum /. LerchPhi[2, 1, n+1] -> lerchSeries[10, n+1], {n, Infinity, 10}] //TeXForm

$\left(\frac{1}{n}+\left(\frac{1}{n}\right)^2+\frac{3}{n^3}+\frac{13}{n^4}+\frac{75}{n^ 5}+\frac{541}{n^6}+\frac{4683}{n^7}+\frac{47293}{n^8}+\frac{545835}{n^9}+\frac{7087 261}{n^{10}}+O\left(\left(\frac{1}{n}\right)^{11}\right)\right) \exp \left(\log (2) n+\log (2)+O\left(\left(\frac{1}{n}\right)^{11}\right)\right)-i \pi$

Answer 2

If nothing else, could check numerically against 2^n/Log[n]. The sum (up to n, so adjust for n-1) is very close to twice that amount:

Table[
 Sum[2.^i/Log[i], {i, 2, n}]/(2^n/Log[n]), {n, 2^Range[2, 15]}]

(* Out[178]= {2.13092975357, 2.18572875976, 2.05561015766, \
2.01956402945, 2.00779127691, 2.00327514385, 2.00142027015, \
2.00062860862, 2.00028230998, 2.000128198777713, 2.00005873009977, \
2.00002709994678, 2.00001258069176, 2.00000587066159} *)

--- edit ---

The actual summand is 2^i/i. This sum has an exact form in terms of the LerchPhi function but that one is not so amenable to direct expansion using Series. So we will approximate the sum with an integral and see how that behaves.

integral = Integrate[2^i/i, {i, 1, n}, Assumptions -> n > 1]

(* Out[209]= -ExpIntegralEi[Log[2]] + ExpIntegralEi[n Log[2]] *)

ser = Series[integral, {n, Infinity, 1}];
Refine[Normal[ser], Assumptions -> n > 1]

(* Out[216]= -ExpIntegralEi[Log[2]] + 2^n/(n Log[2]) *)

So the integral is O(2^n/n). Some numerical testing indicates the sum is as well. This could also be shown by noting that the difference between successive summands and successive integrals from n-1 to n is asymptotically a constant fraction of the summand.

diff = Integrate[2^i/i, {i, n - 1, n}, Assumptions -> n > 2] - 2^n/n;
approxdiff = 
 Together[Refine[
   Normal[Series[diff, {n, Infinity, 1}, Assumptions -> n > 2]], 
   Assumptions -> n > 2]]

(* Out[229]= -((2^(-1 + n) (-1 + 2 Log[2]))/(n Log[2])) *)

--- end edit ---

Answer 3

Some things change to better. In 12.2 on Windows 10Pro

AsymptoticSum[2^i/i, {i, 1, n - 1}, {n, Infinity, 1}]

-2 + 2^n/n