Adding labels to a bar chart with multiple data sets

Question

I am trying to plot multiple data sets on a bar chart with unrelated column labels for each data set...

Suppose my data is a list comprised of three different sub-lists of varying size, i.e., they have the form

{<Data Set 1 (2 Items)>, <Data Set 2 (4 Items)>, <Data Set 3 (8 Items)>}

I want to present the data in a bar chart, where I label each of the sub-lists its own label: Data Set 1 should be labeled {0, 1}, Data Set 2 should be labeled {00, 01, 10, 11} and Data Set 3 should be labeled {000, 001, 010, ..., 111}

How can I accomplish this?

In my current situation, I would like to add the binary expansion listed above to the following bar chart. The last bit of code is obviously wrong, but that's the problem I'm trying to fix.

BarChart[
  {{.45, .55}, 
   {0.25, 0.26, 0.27, 0.22}, 
   {0.125, 0.125, 0, 0.25, 0.25, 0, 0.25, 0}},
  ChartElementFunction -> "GlassRectangle", 
  ChartStyle -> "Pastel",
  ChartLabels -> 
    {{"Order 1", "Order 2", "Order 3"}, 
     {"0", "1", "00", "01", "10", "11", "000", "001", 
      "010", "011", "100", "101", "110", "111"}}]

I

Any help with this issue would be much appreciated, Thanks!

Answer 1

data = {{.45, .55}, {0.25, 0.26, 0.27, 0.22}, {0.125, 0.125, 0, 0.25,  0.25, 0, 0.25, 0}}; 
collabels = {{"0", "1"}, {"00", "01", "10", "11"}, 
    {"000", "001", "010", "011", "100", "101", "110", "111"}};

labeleddata = MapThread[Labeled, #] & /@ Transpose[{data, collabels}] (*thanks: @eldo*)

BarChart[labeleddata, ChartElementFunction -> "GlassRectangle", ChartStyle -> "Pastel", 
 ChartLabels -> {{"Order 1", "Order 2", "Order 3"}, None}]

Alternatively,

rowlabels = {"Order 1", "Order 2", "Order 3"};

BarChart[Labeled @@@ Transpose[{labeleddata, rowlabels}], 
 ChartElementFunction -> "GlassRectangle", ChartStyle -> "Pastel"]

Answer 2

Horrible and kludgy in comparison to @kglr's answer, but may provide a workaround in similar situations. Epilog can often be used to crowbar things in at the last minute:

data = {.45, .55, 0.25, 0.26, 0.27, 0.22, 0.125, 0.125, 0, 0.25, 0.25, 0, 0.25, 0};
barlabels = {"0", "1", "00", "01", "10", "11", "000", "001", "010", "011", "100", "101", "110", "111"};
epilogtext = Text[#[[1]], Scaled[#[[2]]]] & /@ 
   Transpose[{{"Order 1", "Order 2", "Order 3"}, {{0.1, -0.1}, {0.3, -0.1}, {0.7, -0.1}}}];
BarChart[data, ChartElementFunction -> "GlassRectangle", ChartStyle -> "Pastel", 
ChartLabels -> barlabels, Epilog -> epilogtext, ImagePadding -> {{Automatic, Automatic}, {Scaled[0.025], Automatic}}]

Which gives: