How to evaluate the series of (x^a + x)^b when x->Infinity

Question

I want to evaluate the following Series:

Series[(x^a + x)^b, {x, ∞, 1}, Assumptions :> {a > 1, b > 1}], 

but Mathematica simply returns backs the original expression:

(x + x^a)^b

What should I do to get the Series?

Answer 1

To get Mathematica to factor and manipulate expressions with variables in the exponent can seem difficult. In particular Series won't expand an expression like the OP's. Here's an approach that converts the expression into x^(a*b) times an expression that can be expanded in terms of u == x^(1-a). This is done under the assumptions that a, b, x are positive, and further that a > 1 so that the power 1-a may be assumed to be negative.

With[{factor = x^(a*b)},
 expr = factor * Simplify[((x^a + x)^b/factor)^(1/b), b > 0 && a > 0 && x > 0]^b
 ]
(*  x^(a b) (1 + x^(1 - a))^b  *)

sub = x^(1 - a) -> u;
Series[expr /. sub, {u, 0, 3}]
Normal@% /. Reverse[sub]

Answer 2

The main problem is with the $x^a+x$ term. You could try substituting $x\to \frac{1}{x}$ and use explicit values of a to try to discern a pattern:

Series[(1/x^3 + 1/x)^b, {x, 0, 8}] //TeXForm

$\left(\frac{1}{x^3}\right)^b \left(1+b x^2+\frac{1}{2} (b-1) b x^4+\frac{1}{6} (b-2) (b-1) b x^6+\frac{1}{24} (b-3) (b-2) (b-1) b x^8+O\left(x^9\right)\right)$

Series[(1/x^4 + 1/x)^b, {x, 0, 12}] //TeXForm

$\left(\frac{1}{x^4}\right)^b \left(1+b x^3+\frac{1}{2} (b-1) b x^6+\frac{1}{6} (b-2) (b-1) b x^9+\frac{1}{24} (b-3) (b-2) (b-1) b x^{12}+O\left(x^{13}\right)\right)$

Series[(1/x^5 + 1/x)^b, {x, 0, 16}] //TeXForm

$\left(\frac{1}{x^5}\right)^b \left(1+b x^4+\frac{1}{2} (b-1) b x^8+\frac{1}{6} (b-2) (b-1) b x^{12}+\frac{1}{24} (b-3) (b-2) (b-1) b x^{16}+O\left(x^{17}\right)\right)$

Inverting back, it looks like the pattern is:

ser[max_] := x^(a b) Sum[Binomial[b,n] x^(n(1-a)), {n, 0, max}]

We could test this. For example:

exact[x_,a_,b_]:=(x^a+x)^b
approx[x_,a_,b_]:=Evaluate[ser[20]]

exact[1`100*^10,2,3]
exact[1`100*^10,5,6]

1.000000000300000000030000000001000000000000000000000000000000000000000000000000000000000000000000000*10^60

1.00000000000000000000000000000000000000060000000000000000000000000000000000000015000000000000000000*10^300

approx[1`100*^10,2,3]
approx[1`100*^10,5,6]

1.000000000300000000030000000001000000000000000000000000000000000000000000000000000000000000000000000*10^60

1.00000000000000000000000000000000000000060000000000000000000000000000000000000015000000000000000000*10^300