7
$\begingroup$

When I try this

Simplify[(1-a)*(1/(1+x*m))^(1-a)(1+m)^(1-a) + 
         (1-a)*(x*m)^a*((x*m)/(1+x*m))^(1-a)*(1+m)^(1-a)]

the output is

$$\frac{(1-a) (1+m)^{1-a} \left(\left(\frac{1}{1+m x}\right)^{-a}+m x (m x)^a \left(\frac{m x}{1+m x}\right)^{-a}\right)}{1+m x}$$

But a little hand-done algebra shows this reduces to $(1-a) (1+m)^{1-a} (1+mx)^a$.

I tried FullSimplify but get the same results. Is there something I can do to get Mathematica find this simpler form?

$\endgroup$
13
$\begingroup$

Adding assumptions does that:

In[16]:= Simplify[(1 - a)*(1/(1 + x*m))^(1 - a) (1 + m)^(1 - a) + (1 -
      a)*(x*m)^a*((x*m)/(1 + x*m))^(1 - a)*(1 + m)^(1 - a), 
 1 + m x > 0 && a > 0]

Out[16]= -(-1 + a) (1 + m)^(1 - a) (1 + m x)^a

The issue is that (1/x)^a != x^(-a) for all complex $x$ and $a$. Indeed, let $x=-1$ and $a=\frac{1}{2}$:

In[17]:= With[{x = -1, a = 1/2}, {(1/x)^a, x^-a}]

Out[17]= {I, -I}
| improve this answer | |
$\endgroup$
  • 2
    $\begingroup$ Thanks. I'm new to Mathematica, but I suppose it makes sense that it answers the question I ask rather than the question I mean to ask. $\endgroup$ – itzy Nov 15 '12 at 21:21
  • 4
    $\begingroup$ It has become a habit for me to use FullSimplify[expr, _\[Element]Reals] whenever I simplify anything not explicitly complex. $\endgroup$ – ssch Nov 15 '12 at 21:22
3
$\begingroup$

Another approach is to use PowerExpand first which gets you to the same answer.

Simplify[PowerExpand[(1-a)*(1/(1+x*m))^(1-a)(1+m)^(1-a) + 
  (1-a)*(x*m)^a*((x*m)/(1+x*m))^(1-a)*(1+m)^(1-a)]]
| improve this answer | |
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.